blob: 00c46d7dc972a995ae6e1b07a014626b56a8412a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
# Contributor: Denis Kasak <dkasak|AT|termina.org.uk>
# Contributor: Hilton Medeiros <medeiros.hilton at gmail tod com>
# Contributor: Tony Dodd <arch@recalcitrance.net>
# Contributor: Mark Taylor <skymt0@gmail.com>
_pkgname='contextfree'
pkgname="$_pkgname-git"
pkgver=3.4.2.r4.g71dc256
pkgrel=2
pkgdesc='Generates images from written instructions called a grammar (latest commit)'
arch=('aarch64' 'i686' 'x86_64')
url='https://github.com/MtnViewJohn/context-free'
license=('GPL-2.0-or-later') # SPDX-License-Identifier: GPL-2.0-or-later
depends=('gcc-libs' 'glibc' 'icu' 'libpng')
makedepends=('bison' 'flex' 'git')
source=("git+$url.git")
sha256sums=('SKIP')
options=('lto')
provides=("$_pkgname")
conflicts=("$_pkgname")
_srcdir='context-free'
pkgver() {
cd "$_srcdir"
git describe --tags --long \
| sed 's/^Version//;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_srcdir"
make clean
sed -i 's/c++14/c++17/' Makefile
}
build() {
cd "$_srcdir"
# RFC-0023
# 🔗 https://rfc.archlinux.page/0023-pack-relative-relocs/
#
# ld(1) says: “Supported for i386 and x86-64.”
case "Z${CARCH:-unknown}" in
'Zx86_64' | 'Zi386' )
export LDFLAGS="$LDFLAGS -Wl,-z,pack-relative-relocs"
;;
* ) : pass ;;
esac
make
}
package() {
cd "$_srcdir"
install -vDm0755 cfdg "$pkgdir/usr/bin/cfdg"
install -vdm0755 "$pkgdir/usr/share/$pkgname"
cp -vrf input "$pkgdir/usr/share/$pkgname/examples"
}
# eof
|