blob: 9d69c2103c556e1a93665b0fbb5071627f0b3939 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Peter Jung ptr1337 <admin@ptr1337.dev>
# Maintainer: Vladislav Nepogodin <nepogodin.vlad@gmail.com>
pkgname=contour
pkgver=0.4.0.6245
pkgrel=1
pkgdesc="Modern C++ Terminal Emulator"
arch=(x86_64 aarch64)
url="https://github.com/contour-terminal/contour"
license=('Apache-2.0')
depends=('harfbuzz' 'fontconfig' 'yaml-cpp' 'qt6-base' 'qt6-declarative' 'qt6-multimedia'
'qt6-shadertools' 'qt6-wayland' 'qt6-5compat' 'libutempter')
makedepends=('cmake' 'extra-cmake-modules' 'git' 'ninja' 'libxml2'
'python' 'range-v3' 'fmt' 'microsoft-gsl' 'catch2')
source=("$url/archive/refs/tags/v$pkgver.tar.gz")
sha512sums=('8d70cbd19b02196dd1f5c45ab85f5601a3226a1deaba5aa7d83bc79647a04b8945e4555fd735736366df05563a9d2d098b6936f3248e006e1e15ae3aa358170d')
build() {
_cpuCount=$(grep -c -w ^processor /proc/cpuinfo)
CFLAGS=${CFLAGS/-Wp,-D_GLIBCXX_ASSERTIONS}
CXXFLAGS=${CXXFLAGS/-Wp,-D_GLIBCXX_ASSERTIONS}
# Fetch embedded dependencies
PREPARE_ONLY_EMBEDS=ON OS_OVERRIDE=arch ${pkgname}-${pkgver}/scripts/install-deps.sh
cmake -S"${pkgname}-${pkgver}" -Bbuild \
-GNinja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCONTOUR_QT_VERSION=6 \
-DCONTOUR_TESTING=ON
cmake --build build --parallel $_cpuCount
}
check() {
# for running tests, it is (currently) expected to be executed
# from within the source code's project root directory, in order to
# access some test files.
cd "${srcdir}/${pkgname}-${pkgver}"
"${srcdir}"/build/src/contour/contour version
"${srcdir}"/build/src/crispy/crispy_test
"${srcdir}"/build/src/vtparser/vtparser_test
"${srcdir}"/build/src/vtbackend/vtbackend_test
}
package() {
cd "${srcdir}/build"
DESTDIR="${pkgdir}" cmake --build . --target install
cd "${srcdir}/${pkgname}-${pkgver}"
install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set sw=2 sts=2 et:
|