blob: ad717a1efb8223aa371be93f24eaefac3c299e17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
pkgname=cookcli
_pkgname=cook
pkgver=0.22.0
pkgrel=1
pkgdesc="Suite of tools to create shopping lists and maintain recipes"
arch=('x86_64')
url="https://github.com/cooklang/cookcli"
license=('MIT')
depends=('gcc-libs' 'openssl')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('3ea0000d86b3420d8862dacc047ce646a0f18857a91a88ec4c2acc245b738afdf7d8d48636d60bee2abc608b5b2dd59b8248d44f676a0f524c42e4d32e4fa04e')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen --no-default-features
}
check() {
cd "$pkgname-$pkgver"
cargo test --frozen --no-default-features -- --skip "test_help_output"
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/$_pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim: ts=2 sw=2 et:
|