blob: def1f01f11f9b3eb31c514bb8c05889278282b12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Eren Simsek <18117384-caferen@users.noreply.gitlab.com>
# Contributor: Guy Boldon <gb@guyboldon.com>
pkgname=coolercontrold-bin
_pkgname="${pkgname%-bin}"
pkgver=2.2.0
pkgrel=1
pkgdesc="A program to monitor and control your cooling devices: daemon (binary release)"
arch=('x86_64')
url="https://gitlab.com/coolercontrol/coolercontrol"
license=('GPL-3.0-or-later')
depends=(
'libdrm'
'gcc-libs'
'glibc'
)
optdepends=(
'nvidia-utils: NVIDIA GPU support'
'coolercontrol-liqctld'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
groups=(coolercontrol-bin)
source=(
"https://gitlab.com/coolercontrol/coolercontrol/-/releases/$pkgver/downloads/packages/${_pkgname}_${pkgver}"
"https://gitlab.com/coolercontrol/coolercontrol/-/archive/$pkgver/coolercontrol-$pkgver.tar.gz"
)
sha256sums=(
'd4af3c627ea62d83ac32c98f94d95ccb0187d4827b8e71693c6a72ef0802df55'
'89057c77bbe7ae2c0523578a5a6e408d5af033c432aa9b9f810c256ec7e39f9e'
)
check() {
chmod +x "./${_pkgname}_${pkgver}"
"./${_pkgname}_${pkgver}" --version
}
package() {
install -DTm755 "./${_pkgname}_${pkgver}" "$pkgdir/usr/bin/${_pkgname}"
cd "${srcdir}/${pkgname%d-bin}-$pkgver"
# systemd service file
install -Dm644 "packaging/systemd/$_pkgname.service" -t "$pkgdir/usr/lib/systemd/system/"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/$_pkgname"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
}
|