blob: c1f06e017dc306068bc95352c0a711459b61462f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Guy Boldon <gb@guyboldon.com>
pkgname=coolero
_app_id="org.$pkgname.Coolero"
pkgver=0.12.4
pkgrel=2
pkgdesc="A program to monitor and control your cooling devices"
arch=('any')
url="https://gitlab.com/coolero/coolero"
license=('GPL3')
depends=('hicolor-icon-theme' 'polkit' 'python' 'liquidctl' 'pyside6' 'qt6-svg' 'python-apscheduler'
'python-matplotlib' 'python-numpy' 'python-psutil' 'python-setproctitle' 'python-jeepney'
'python-pyamdgpuinfo')
makedepends=('python-build' 'python-installer' 'python-poetry')
checkdepends=('appstream-glib' 'desktop-file-utils')
optdepends=('nvidia-utils: NVIDIA GPU support')
provides=("$pkgname")
conflicts=("$pkgname")
source=("https://gitlab.com/coolero/coolero/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('dd91eb09f1bb6f67b9e5f8a22bb3999d2d3c41708c1fc1f61c27e742fde455e5')
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$pkgname-$pkgver"
desktop-file-validate "metadata/$_app_id.desktop"
#appstream-util validate-relax "metadata/$_app_id.metainfo.xml"
python -m coolero -v
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
# systemd service files
install -Dm644 "packaging/systemd/${pkgname}d.service" -t "$pkgdir/usr/lib/systemd/system/"
install -Dm644 "packaging/systemd/${pkgname}d.socket" -t "$pkgdir/usr/lib/systemd/system/"
install -Dm644 "packaging/systemd/${pkgname}.conf" -t "$pkgdir/usr/lib/sysusers.d/"
# desktop metadata
install -Dm644 "metadata/$_app_id.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "metadata/$_app_id.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
install -Dm644 "metadata/$_app_id.png" -t "$pkgdir/usr/share/pixmaps/"
install -Dm644 "metadata/$_app_id.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
}
|