blob: 16c4016edec4fbedae869567efecebdfaf44cb64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=copperspice
pkgver=1.7.1
pkgrel=2
pkgdesc='Libraries for developing cross platform software applications in C++'
arch=('x86_64')
url='https://www.copperspice.com/'
license=('LGPL2.1')
depends=('cups' 'fontconfig' 'glib2' 'gstreamer' 'gst-plugins-base-libs' 'libgl'
'libice' 'libpulse' 'libsm' 'libx11' 'libxcb' 'libxi' 'libxkbcommon'
'libxkbcommon-x11' 'openssl' 'xcb-util-keysyms' 'xcb-util-image'
'xcb-util-renderutil' 'xcb-util-wm' 'zlib')
optdepends=('mariadb-libs: for MySQL database support'
'postgresql-libs: for PostgreSQL database support')
makedepends=('cmake' 'alsa-lib' 'mariadb-libs' 'postgresql' 'postgresql-libs'
'libxcursor' 'libxext' 'libxfixes' 'libxinerama' 'libxrandr'
'libxrender' 'libxml2')
source=("https://github.com/copperspice/copperspice/archive/cs-${pkgver}/${pkgname}-${pkgver}.tar.gz"
'010-copperspice-fix-cmake-include-dirs.patch')
sha256sums=('2e74c809f6e9bffbe53f2f758b280781f6905631d9647717b47bc9202dba0d41'
'14c52854ed1d92430a4b4ce6dd967f86141cc3352784b2396f786575bac0bdd0')
prepare() {
patch -d "copperspice-cs-${pkgver}" -Np1 -i "${srcdir}/010-copperspice-fix-cmake-include-dirs.patch"
}
build() {
cmake -B build -S "copperspice-cs-${pkgver}" \
-DCMAKE_BUILD_TYPE:STRING='None' \
-DCMAKE_INSTALL_BINDIR:PATH='lib/copperspice/bin' \
-DCMAKE_INSTALL_INCLUDEDIR:PATH='include/copperspice' \
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-Wno-dev
make -C build
}
package() {
make -C build DESTDIR="$pkgdir" install
local _file
mkdir -p "${pkgdir}/usr/bin"
while read -r -d '' _file
do
ln -s "../lib/copperspice/bin/${_file##*/}" "${pkgdir}/usr/bin/${_file##*/}-cs"
done < <(find "${pkgdir}/usr/lib/copperspice/bin" -type f -executable -print0)
}
|