blob: ee9c3491ab9a914c42a039d8b5d7807f732d04bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=copperspice-git
pkgver=2.1.0.r0.gcbad1f991
pkgrel=2
pkgdesc='Libraries for developing cross platform software applications in C++ (git version)'
arch=('x86_64')
url='https://www.copperspice.com/'
license=('LGPL-2.1-only')
depends=(
'fontconfig'
'gcc-libs'
'glib2'
'glibc'
'gst-plugins-base-libs'
'gstreamer'
'libcups'
'libgl'
'libice'
'libjpeg'
'libpulse'
'libsm'
'libx11'
'libxcb'
'libxi'
'libxkbcommon'
'libxkbcommon-x11'
'openssl' # loaded on demand by QLibrary
'sqlite'
'vulkan-icd-loader'
'wayland'
'xcb-util-image'
'xcb-util-keysyms'
'xcb-util-renderutil'
'xcb-util-wm'
'zlib')
optdepends=(
'gtk2: for GTK2 GUI style'
'mariadb-libs: for MySQL database support'
'postgresql-libs: for PostgreSQL database support')
makedepends=(
'cmake'
'alsa-lib'
'git'
'mariadb-libs'
'postgresql'
'postgresql-libs'
'vulkan-headers'
'libxcursor'
'libxext'
'libxfixes'
'libxinerama'
'libxrandr'
'libxrender'
'libxml2')
provides=('copperspice')
conflicts=('copperspice')
options=('!lto')
source=('git+https://github.com/copperspice/copperspice.git'
'010-copperspice-fix-cmake-include-dirs.patch'
'020-copperspice-fix-werror-format-security-without-wformat.patch')
sha256sums=('SKIP'
'db23a35f0651ac20d979d2b6e462f1cdc2d91a0315c60ccf513a33cc2ebdc1ed'
'6190590c3ac496923ccbc80189a1d488531071392390e7bdd57c081c31d6eb16')
prepare() {
patch -d copperspice -Np1 -i "${srcdir}/010-copperspice-fix-cmake-include-dirs.patch"
patch -d copperspice -Np1 -i "${srcdir}/020-copperspice-fix-werror-format-security-without-wformat.patch"
}
pkgver() {
git -C copperspice describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^cs\.//'
}
build() {
cmake -B build -S copperspice \
-G 'Unix Makefiles' \
-DCMAKE_BUILD_TYPE:STRING='None' \
-DCMAKE_INSTALL_BINDIR:PATH='lib/copperspice/bin' \
-DCMAKE_INSTALL_INCLUDEDIR:PATH='include/copperspice' \
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-DCMAKE_SKIP_RPATH:BOOL='YES' \
-Wno-dev
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
local _file
install -d -m755 "${pkgdir}/usr/bin"
while read -r -d '' _file
do
ln -s "../lib/copperspice/bin/${_file##*/}" "${pkgdir}/usr/bin/${_file##*/}-cs"
done < <(find "${pkgdir}/usr/lib/copperspice/bin" -type f -executable -print0)
}
|