PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# $Id:
# Maintainer: Ivailo Monev <xakepa10@gmail.com>

pkgname=copperspice-git
pkgver=1.2.0.03c219e
pkgrel=1
pkgdesc='C++ library derived from the existing Qt 4.8 framework'
arch=('i686' 'x86_64')
url='http://www.copperspice.com/'
license=('LGPL' 'FDL' 'custom')
depends=('openssl' 'zlib' 'cups' 'alsa-lib' 'gtk2' 'nas' 'libgl' 'libice'
        'libsm' 'libxcursor' 'libxext' 'libxfixes' 'libxi' 'libxinerama'
        'libxrandr' 'libxrender' 'libx11' 'fontconfig' 'freetype2' 'glib2'
        'gstreamer0.10-base-plugins' 'libxml2')
makedepends=('cmake' 'git' 'postgresql' 'mariadb' 'mesa')
optdepends=('postgresql-libs: PostgreSQL driver'
        'libmariadbclient: MariaDB driver')
source=("git+https://github.com/fluxer/copperspice.git#branch=cs-1.2")
sha1sums=('SKIP')
conflicts=('copperspice')
options=('debug')

pkgver() {
    cd copperspice
    printf "1.2.0.%s" "$(git rev-parse --short HEAD)"
}

prepare() {
    mkdir -p build
}

build() {
    cd build
    cmake ../copperspice \
        -DCMAKE_BUILD_TYPE=RelWithDbgInfo \
        -DCMAKE_SKIP_RPATH=OFF \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_SYSCONFDIR=/etc \
        -DCMAKE_INSTALL_INCLUDEDIR=include/copperspice \
        -DTOOLS_SUFFIX=-cs \
        -DWITH_WEBKIT=ON
    make
}

package() {
    cd build
    make DESTDIR="${pkgdir}" install

    install -vDm644 ../copperspice/license/LGPL_EXCEPTION.txt \
        "${pkgdir}/usr/share/licenses/copperspice-git/LGPL_EXCEPTION.txt"
}