blob: b9f3fcab9230e79623b87273a7de0f7a763fc36b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: Baptiste Jonglez <baptiste--aur at jonglez dot org>
# Contributor: acieroid
# Contributor: spider-mario <spidermario@free.fr>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: George Giorgidze <giorgidze@gmail.com>
# Contributor: William J. Bowman <bluephoenix47@gmail.com>
pkgname=('coq' 'coqide' 'coq-doc')
pkgver=8.6
pkgrel=4
pkgdesc='Formal proof management system'
arch=('i686' 'x86_64')
url='https://coq.inria.fr/'
license=('GPL')
groups=('coq')
options=('!emptydirs')
depends=('ocaml' 'camlp4' 'gtk2' 'gtksourceview2')
makedepends=('ocaml-findlib'
'lablgtk2' 'gendesk' # coqide
'texlive-bin' 'texlive-latexextra' 'texlive-pictures' # coq-doc
'texlive-fontsextra' 'texlive-science'
'fig2dev' 'imagemagick' 'hevea' 'ghostscript')
source=("https://coq.inria.fr/distrib/V$pkgver/files/coq-$pkgver.tar.gz"
"0001-Fix-incorrect-documentation-that-prevents-successful.patch"
"0002-Avoid-concurrent-runs-when-producing-html-documentat.patch")
sha1sums=('617a6f86d09dde0e409f3fa22268daf7be3f5bba'
'ec5e9af33f37d2eb154f8de13815cb7f1f2fba6e'
'201f1db7fd3e7e072ff7c94cfcdabdcc5910ccdd')
prepare() {
gendesk -f -n --pkgname "coqide" \
--name "CoqIDE Proof Assistant" \
--pkgdesc "Graphical interface for the Coq proof assistant" \
--categories "Development;Science;Math;IDE;GTK"
cd "$srcdir/coq-$pkgver"
patch -p1 < ../0001-Fix-incorrect-documentation-that-prevents-successful.patch
patch -p1 < ../0002-Avoid-concurrent-runs-when-producing-html-documentat.patch
}
build() {
cd "$srcdir/coq-$pkgver"
./configure \
-prefix '/usr' \
-mandir '/usr/share/man' \
-configdir '/etc/xdg/coq/' \
-coqide opt \
-with-doc yes \
-usecamlp4
make world
}
package_coq() {
depends=('ocaml' 'camlp4')
optdepends=('coqide: graphical Coq IDE'
'coq-doc: offline documentation')
# coq-nox was the old name for coq without coqide
replaces=('coq-nox')
conflicts=('coq-nox')
cd "$srcdir/coq-$pkgver"
# The second target is needed to install coqidetop.cmxs (needed for some
# frontend other than coqide, for instance coquille)
make COQINSTALLPREFIX="$pkgdir" install-coq install-ide-toploop
rm -f "${pkgdir}/usr/share/man/man1/coqide.1"
}
package_coqide() {
pkgdesc="GTK-based graphical interface for the Coq proof assistant"
depends=('coq' 'ocaml' 'camlp4' 'gtk2' 'gtksourceview2')
cd "$srcdir/coq-$pkgver"
make COQINSTALLPREFIX="$pkgdir" install-coqide
install -D -m 644 -t "${pkgdir}/usr/share/man/man1/" man/coqide.1
# Remove toploop files installed by "install-ide-toploop" in the main package
rm -f "${pkgdir}/usr/lib/coq/toploop"/coqidetop.{cma,cmxs}
# Desktop file generated by gendesk
install -D -m 644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -D -m 644 ide/coq.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}
package_coq-doc() {
pkgdesc="HTML and PDF documentation for the Coq proof assistant"
depends=()
arch=('any')
cd "$srcdir/coq-$pkgver"
make COQINSTALLPREFIX="$pkgdir" install-doc
}
|