blob: c7f02c7fd72897741ad399567a9893c4157e38e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Anatol Pomozov
# Maintainer: Iru Cai <mytbk920423@gmail.com>
pkgname=coreboot-utils-git
pkgver=4.6.r2177.g73add175cd
pkgrel=1
pkgdesc='Tools and utilities to work with coreboot firmware'
url='https://www.coreboot.org/'
license=(GPL)
arch=(i686 x86_64)
depends=(pciutils)
optdepends=("python: me_cleaner support")
makedepends=(git)
source=(git+https://review.coreboot.org/coreboot
# vboot provides vb2_api.h needed by cbfstool
git+https://review.coreboot.org/vboot
https://raw.githubusercontent.com/corna/me_cleaner/312ef02714dcab806c9d9bfee07f51002dc61e08/me_cleaner.py)
sha256sums=('SKIP'
'SKIP'
'f27ddd0fa26c121221dc8f76b71bf308d6d7c48fdc4d84968580d04c5dc2e42e')
BUILD_AUTOPORT=y
if [ "$BUILD_AUTOPORT" == y ]; then
makedepends=("${makedepends[@]}" go)
fi
pkgver() {
cd coreboot
git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd coreboot
git submodule init
git config -f .gitmodules 'submodule.vboot.url' "$srcdir/vboot"
git submodule sync -- 3rdparty/vboot
git submodule update -- 3rdparty/vboot
}
build() {
cd coreboot/util
make -C cbfstool
make -C ifdtool
make -C nvramtool
make -C inteltool
make -C intelmetool
make -C superiotool
make -C cbmem
make -C romcc romcc # tests fail
make -C ectool
if [ "$BUILD_AUTOPORT" == y ]; then
cd autoport
go build
fi
}
package() {
cd coreboot/util
install -m755 -d "$pkgdir/usr/bin" "$pkgdir/usr/share/man/man8"
install -m755 -t "$pkgdir/usr/bin" cbfstool/{cbfstool,rmodtool} ifdtool/ifdtool nvramtool/nvramtool inteltool/inteltool superiotool/superiotool cbmem/cbmem romcc/romcc ectool/ectool intelmetool/intelmetool
install -m755 "$srcdir/me_cleaner.py" "$pkgdir/usr/bin/me_cleaner"
if [ "$BUILD_AUTOPORT" == y ]; then
install -m755 -t "$pkgdir/usr/bin" autoport/autoport
fi
install -m644 -t "$pkgdir"/usr/share/man/man8 inteltool/inteltool.8
install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
|