blob: 3a90f85e57f252ccd78e169ef55d69ab5c357890 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Leonidas Spyropoulos <artafinde at gmail dot com>
# Contributor: CyrIng <labs[at]cyring[dot]fr>
pkgbase=corefreq
pkgname=(corefreq-client corefreq-server corefreq-dkms)
_gitname=CoreFreq
pkgver=1.84
pkgrel=2
arch=('x86_64')
url='https://github.com/cyring/CoreFreq'
license=('GPL2')
depends=('dkms')
source=(${pkgbase}-${pkgver}.tar.gz::"${url}/archive/${pkgver}.tar.gz"
'dkms.conf'
"fix-for-5.12.patch::https://github.com/cyring/CoreFreq/commit/f6a350bafae6cc67ac9a5ec636f126a01c7df0f7.patch")
b2sums=('c4f956b785ada9a9cfcc508a28e2146cab756cc4da67c25f7c67826e6a921079f95139deadeaae9621231bb982a682db5eee3eec4c760cbf929226aa036a6deb'
'c6d8849944f99195038ac252d010d3e3001cd1dcaee57218c4a7f58fa313aa38842e4ea991d4d9ff7d04063ebaa9900c06ff1eacfa6270341cf37fb752adc00c'
'16d6eb223a4562e6d7bec2f014a3c358e4e141e44e7520bbcb8e805cabfac883a17f54ce82e6d75e3965a7b607697952520c4517ba1195e0481796932933f638')
prepare() {
cd "${_gitname}-${pkgver}"
patch -Np1 < "../fix-for-5.12.patch"
}
build() {
cd "${_gitname}-${pkgver}"
make corefreqd corefreq-cli
}
package_corefreq-dkms() {
pkgdesc="CoreFreq - kernel module sources"
depends=('dkms')
provides=("corefreq-dkms=$pkgver")
_kernelmodule=corefreqk
# Copy simple dkms.conf
install -Dm644 dkms.conf "${pkgdir}/usr/src/${pkgbase}-${pkgver}/dkms.conf"
# Set name and version
sed -e "s/@_PKGBASE@/${pkgbase}/" \
-e "s/@PKGVER@/${pkgver}/" \
-e "s/@_KERNELMODULE@/${_kernelmodule}/" \
-i "${pkgdir}/usr/src/${pkgbase}-${pkgver}/dkms.conf"
# Copy sources (including Makefile)
cp -r "${_gitname}-${pkgver}"/{*.c,*.h,Makefile} "${pkgdir}/usr/src/${pkgbase}-${pkgver}/"
}
package_corefreq-server() {
pkgdesc="CoreFreq server"
depends=("corefreq-dkms=$pkgver")
provides=('corefreq-server')
cd "${_gitname}-${pkgver}"
install -Dm755 corefreqd "${pkgdir}/usr/bin/corefreqd"
install -Dm 0644 corefreqd.service "${pkgdir}/usr/lib/systemd/system/corefreqd.service"
}
package_corefreq-client() {
pkgdesc="CoreFreq client"
depends=("corefreq-server=$pkgver")
provides=('corefreq-client')
cd "${_gitname}-${pkgver}"
install -Dm755 corefreq-cli "${pkgdir}/usr/bin/corefreq-cli"
}
|