blob: d61cbd9fd7ffe0b3359385afa868c17f4d3d729a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Leonidas Spyropoulos <artafinde at gmail dot com>
# Contributor: CyrIng <labs[at]cyring[dot]fr>
pkgbase=corefreq-git
pkgname=(corefreq-client-git corefreq-server-git corefreq-dkms-git)
_gitname=CoreFreq
_pkgbase=${pkgbase%-*}
pkgver=1.97.0.r102.g77ddd76
pkgrel=1
pkgdesc="A CPU monitoring software with BIOS like functionalities"
arch=('x86_64')
url='https://github.com/cyring/CoreFreq'
license=('GPL-2.0-only')
depends=('dkms')
makedepends=('git')
source=(git+"${url}.git#branch=develop"
'dkms.conf'
'honor-archlinux-compiler-flags.patch')
b2sums=('SKIP'
'a47306b69244b2c7cfe34a5a19aabc7d22ef8982402da038bfb65a357bed9aa0d9f30b034afa7c6dbc23969448142a0027bd14364a14da92b1c666881e15420c'
'f4299ed5c44052a521988d417410081ddb92a5f481012f9c7a964ec0dee6a63be6123cef8f8618f23be6827e25aeb3fef93f8c270aaa3076cc1f434a6d4ca861')
pkgver() {
cd "${_gitname}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare(){
cd "${_gitname}"
patch -Np1 < "$srcdir/honor-archlinux-compiler-flags.patch"
}
build() {
cd "${_gitname}"
make prepare corefreqd corefreq-cli -j
}
package_corefreq-dkms-git() {
pkgdesc="CoreFreq - kernel module sources"
depends=('dkms')
provides=("corefreq-dkms")
conflicts=('corefreq-dkms')
_kernelmodule=corefreqk
# Copy simple dkms.conf
install -Dm644 dkms.conf "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/dkms.conf"
# Set name and version
sed -e "s/@_PKGBASE@/${_pkgbase}/" \
-e "s/@PKGVER@/${pkgver}/" \
-e "s/@_KERNELMODULE@/${_kernelmodule}/" \
-i "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/dkms.conf"
# Copy sources (including Makefile)
cp -r "${_gitname}"/{Makefile,scripter.sh} "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/"
cp -r "${_gitname}"/${CARCH} "${pkgdir}/usr/src/${_pkgbase}-${pkgver}/"
}
package_corefreq-server-git() {
pkgdesc="CoreFreq server"
depends=("corefreq-dkms")
provides=('corefreq-server')
conflicts=('corefreq-server')
cd "${_gitname}"
install -Dm755 build/corefreqd "${pkgdir}/usr/bin/corefreqd"
install -Dm 0644 corefreqd.service "${pkgdir}/usr/lib/systemd/system/corefreqd.service"
}
package_corefreq-client-git() {
pkgdesc="CoreFreq client"
depends=("corefreq-server")
provides=('corefreq-client')
conflicts=('corefreq-client')
cd "${_gitname}"
install -Dm755 build/corefreq-cli "${pkgdir}/usr/bin/corefreq-cli"
}
|