blob: 6118b7818b54929cad8fdc97e2a055ed79a6440c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: ovi chis <sonekken@gmail.com>
pkgname=corosync-git
_pkgname=corosync
pkgver=2.4.2.r25.g2901ecea
pkgrel=1
pkgdesc="Cluster engine for nodal communication systems with additional features for implementing high availability within applications."
arch=('i686' 'x86_64')
url="http://www.corosync.org/"
license=('BSD')
makedepends=('git')
depends=('nss' 'libstatgrab' 'net-snmp' 'libdbus' 'libqb')
provides=(${_pkgname})
conflicts=(${_pkgname})
source=("$pkgname::git+https://github.com/corosync/${_pkgname}.git#branch=needle")
md5sums=('SKIP')
pkgver() {
cd $pkgname
git describe --long --tags | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd $pkgname
./autogen.sh
}
build() {
cd $pkgname
./configure --sbindir=/usr/bin \
--sysconfdir=/etc \
--libdir=/usr/lib \
--localstatedir=/var \
--enable-dbus \
--enable-monitoring \
--enable-watchdog \
--enable-systemd \
--disable-upstart \
--enable-snmp \
--enable-xmlconf \
--with-systemddir=/usr/lib/systemd/system \
--with-tmpfilesdir=/usr/lib/tmpfiles.d
make V=0
}
package() {
cd $pkgname
make DESTDIR="${pkgdir}" install
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
rm -fr "${pkgdir}/var/log"
install -Dm644 /dev/null "${pkgdir}/usr/lib/tmpfiles.d/corosync.conf"
echo "d /var/log/cluster 0755 root root -" \
>"${pkgdir}/usr/lib/tmpfiles.d/corosync.conf"
}
# vim: set sw=2 et:
|