summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e8125850b7f085956aace241982184be08e287db (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Maintainer: Patrick Jennings <patrick at jenningsga dot com>

pkgname=corosync-qdevice
pkgver=3.0.0
pkgrel=1
pkgdesc="The Corosync Cluster Engine Qdevice"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://www.corosync.org/"
license=('BSD')
depends=('corosync')
source=("$pkgname-$pkgver.tar.gz::https://github.com/corosync/$pkgname/archive/v$pkgver.tar.gz")
sha256sums=('06b6ba6bd34186a13e645b962cbcf0ebf644227688e3578e239632c82243ab3c')

prepare() {
  cd ${pkgname}-${pkgver}
  ./autogen.sh
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --sbindir=/usr/bin \
              --sysconfdir=/etc \
              --libdir=/usr/lib \
              --enable-dbus \
              --enable-monitoring \
              --enable-watchdog \
              --enable-systemd \
              --disable-upstart \
              --enable-snmp \
              --enable-xmlconf \
              --enable-qdevices \
              --enable-qnetd \
              --localstatedir=/var \
              --with-systemddir=/usr/lib/systemd/system \
              --with-tmpfilesdir=/usr/lib/tmpfiles.d
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install

  rm -r "$pkgdir/var/run"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: set sw=2 et: