blob: 9a1448a63ca80080ec26c0f06af0015f8ea1e0d4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Jonathan Capps <hello at cappsy dot dev>
pkgname=cosmic-ext-applet-dict-git
pkgver=v0.1.3.r2.g4fef6df
pkgrel=1
pkgdesc="An English language dictionary applet for the COSMIC™ desktop"
arch=('x86_64' 'aarch64')
url="https://github.com/cosmic-utils/cosmic-ext-applet-dict"
license=('GPL-3.0-or-later')
depends=('cosmic-applets')
makedepends=(
'cargo'
'git'
'just'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/cosmic-utils/cosmic-ext-applet-dict.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
just build-release --frozen
}
package() {
cd "${pkgname%-git}"
just rootdir="$pkgdir" install
}
|