PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: smiley <smiley@aur.archlinux.org>

pkgname=cosmic-ext-applet-kdeconnect
pkgver=0.10.0
pkgrel=1
pkgdesc='Native KDE Connect applet for the COSMIC desktop'
arch=('x86_64' 'aarch64')
options=('!lto')
url='https://github.com/cosmic-utils/kdeconnect'
license=('GPL-3.0-only')
depends=(
  'cosmic-applets'
  'libpulse'
)
makedepends=('cargo' 'just' 'cmake' 'go' 'clang' 'lld')
provides=('cosmic-ext-applet-kdeconnect')
conflicts=('cosmic-ext-applet-kdeconnect-git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/cosmic-utils/kdeconnect/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('52477c895c8781742a8debb9ec12cee9a739c41fcd863b987fdbc41a194d04e9')

prepare() {
  cd "kdeconnect-$pkgver"
  cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "kdeconnect-$pkgver"
  CARGO_PROFILE_RELEASE_LTO=false cargo build --release --frozen
}

package() {
  cd "kdeconnect-$pkgver"
  local d="$pkgdir/usr"

  install -Dm755 target/release/kdeconnect-service          "$d/bin/kdeconnect-service"
  install -Dm755 target/release/cosmic-ext-connect-applet   "$d/bin/cosmic-ext-connect-applet"
  install -Dm755 target/release/cosmic-ext-connect-settings "$d/bin/cosmic-ext-connect-settings"
  install -Dm755 target/release/cosmic-ext-connect-sms      "$d/bin/cosmic-ext-connect-sms"

  install -Dm644 resources/io.github.hepp3n.kdeconnect.svg \
    "$d/share/icons/hicolor/scalable/apps/io.github.hepp3n.kdeconnect.svg"
  install -Dm644 resources/io.github.hepp3n.kdeconnect.metainfo.xml \
    "$d/share/metainfo/io.github.hepp3n.kdeconnect.metainfo.xml"

  install -d "$d/share/applications"
  sed 's|Exec=cosmic-ext-connect-applet|Exec=/usr/bin/cosmic-ext-connect-applet|' \
    resources/io.github.hepp3n.kdeconnect.desktop \
    > "$d/share/applications/io.github.hepp3n.kdeconnect.desktop"
  install -Dm644 resources/io.github.hepp3n.kdeconnect.settings.desktop \
    "$d/share/applications/io.github.hepp3n.kdeconnect.settings.desktop"
  install -Dm644 resources/io.github.hepp3n.kdeconnect.sms.desktop \
    "$d/share/applications/io.github.hepp3n.kdeconnect.sms.desktop"

  mkdir -p "$d/share/dbus-1/services"
  printf '[D-BUS Service]\nName=io.github.hepp3n.kdeconnect\nExec=/usr/bin/kdeconnect-service\n' \
    > "$d/share/dbus-1/services/io.github.hepp3n.kdeconnect.service"
}