blob: fabc91edcb58becbae9060e65b124d9f23cd5896 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-ext-calculator-git
_app_id=dev.edfloreshz.Calculator
pkgver=0.2.0.r9.g29853d5
pkgrel=1
pkgdesc="Calculator for the COSMIC desktop."
arch=('x86_64' 'aarch64')
url="https://github.com/cosmic-utils/calculator"
license=('GPL-3.0-or-later')
depends=(
'hicolor-icon-theme'
'libxkbcommon'
)
makedepends=(
'cargo'
'clang'
'git'
'just'
'mold'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/cosmic-utils/calculator.git')
sha256sums=('SKIP')
pkgver() {
cd calculator
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd calculator
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc --print host-tuple)"
}
build() {
cd calculator
export RUSTUP_TOOLCHAIN=stable
export CC=clang
RUSTFLAGS+=" -C link-arg=-fuse-ld=mold"
just build-release --frozen
}
package() {
cd calculator
just rootdir="$pkgdir" install
}
|