PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-ext-forecast-git
pkgver=r73.75e6cf9
pkgrel=1
pkgdesc="Weather app written in rust and libcosmic"
arch=('x86_64' 'aarch64')
url="https://github.com/cosmic-utils/forecast"
license=('GPL-3.0-or-later')
depends=('hicolor-icon-theme' 'libxkbcommon' 'openssl')
makedepends=('cargo' 'git' 'just')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/cosmic-utils/forecast.git')
sha256sums=('SKIP')

pkgver() {
  cd forecast
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
  cd forecast
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd forecast
  export RUSTUP_TOOLCHAIN=stable
  just build-release --frozen
}

package() {
  cd forecast
  just rootdir="$pkgdir" install
}