blob: 1c6c7e2e92b4c4a0e8d9c5fe0d0b911184ebde61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-launcher-git
pkgver=1.0.8.r7.ga3d950b
pkgrel=1
pkgdesc="Layer Shell frontend for Pop Launcher."
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/cosmic-launcher"
license=('GPL-3.0-only')
depends=(
'hicolor-icon-theme'
'libxkbcommon'
'pop-launcher-git'
'wayland'
)
makedepends=(
'cargo'
'clang'
'git'
'intltool'
'just'
'mold'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/pop-os/cosmic-launcher.git'
'lto.patch')
sha256sums=('SKIP'
'852bbae9d79b0ababff4e0cc9e79ff3511622f1511cd854c5b176cba6928cde6')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags --abbrev=7 | sed 's/^epoch-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
# Use thin LTO
patch -Np1 -i ../lto.patch
export RUSTUP_TOOLCHAIN=stable
cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
# use nice to build with lower priority
nice just build-release
}
package() {
cd "${pkgname%-git}"
just rootdir="$pkgdir" install
}
|