blob: 9536a439703e25f3cd368f677f4d5fccb41a6282 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-osd-git
pkgver=1.0.0.beta.8.r12.g47f715a
pkgrel=2
pkgdesc="COSMIC On-Screen Display"
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/cosmic-osd"
license=('GPL-3.0-only')
depends=(
'cosmic-randr-git'
'libinput'
'libpipewire'
'libpulse'
'libxkbcommon'
'sound-theme-freedesktop'
'systemd-libs'
'wayland'
)
makedepends=(
'cargo'
'clang'
'git'
'just'
'mold'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/pop-os/cosmic-osd.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags --abbrev=7 | sed 's/^epoch-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc --print host-tuple)"
}
build() {
cd "${pkgname%-git}"
export RUSTUP_TOOLCHAIN=stable
# use mold instead of lld to speed up build
RUSTFLAGS+=" -C link-arg=-fuse-ld=mold"
# use nice to build with lower priority
nice just polkit-agent-helper-1="/usr/lib/polkit-1/polkit-agent-helper-1" build-release --frozen
}
package() {
cd "${pkgname%-git}"
just rootdir="$pkgdir" install
}
|