blob: 6fbff6d612d0bb5a5b9cffaa3b71df3817f9bb19 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-settings-daemon-git
pkgver=r65.81a5305
pkgrel=1
pkgdesc="Cosmic settings daemon"
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/cosmic-settings-daemon"
license=('GPL-3.0-or-later')
groups=('cosmic')
depends=(
'acpid'
'adw-gtk3'
'geoclue'
'libinput'
'systemd-libs'
)
makedepends=(
'cargo'
'git'
'mold'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/pop-os/cosmic-settings-daemon.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "${pkgname%-git}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
make vendor
sed -i 's|libexec|lib|g' Makefile src/main.rs
}
build() {
cd "${pkgname%-git}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
# use mold instead of lld to speed up build
RUSTFLAGS="-C link-arg=-fuse-ld=mold"
# use nice to build with lower priority
nice make prefix='/usr' VENDOR='1' all
}
package() {
cd "${pkgname%-git}"
make prefix='/usr' DESTDIR="$pkgdir" install
}
|