blob: f9e5c0bf8b86ac4d6c2b856c2793cd92a06dc2d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-store-git
pkgver=r184.8f13d37
pkgrel=1
pkgdesc="WIP COSMIC app store"
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/cosmic-store"
license=('GPL-3.0-or-later')
groups=('cosmic')
depends=(
'archlinux-appstream-data'
'gcc-libs'
'hicolor-icon-theme'
)
makedepends=(
'cargo'
'flatpak'
'git'
'just'
'mold'
)
optdepends=(
'flatpak: Flatpak packages support'
'packagekit: package manager integration module'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/pop-os/cosmic-store.git'
'git+https://github.com/jackpot51/appstream.git')
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${pkgname%-git}"
git submodule init
git config submodule.appstream.url "$srcdir/appstream"
git -c protocol.file.allow=always submodule update
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
just vendor
}
build() {
cd "${pkgname%-git}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
# use mold instead of lld to speed up build
RUSTFLAGS="-C link-arg=-fuse-ld=mold"
# use nice to build with lower priority
nice just build-vendored
}
package() {
cd "${pkgname%-git}"
just rootdir="$pkgdir" install
}
|