blob: 1d3805de5369217226d1a3f4c29adbd29342615c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Runnytu < runnytu at gmail dot com >
# Old Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: Tobias Kieslich <tobias@justdreams.de>
pkgname=courier-maildrop
_srcname=maildrop
pkgver=2.9.3
pkgrel=1
pkgdesc="mail delivery agent - procmail like but nicer syntax"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://courier-mta.org/maildrop/"
depends=('courier-authlib>=0.68.0' 'gamin' 'pcre' 'gdbm' 'courier-unicode>=2.0')
conflicts=('courier-mta')
options=('!libtool' '!staticlibs')
source=(http://downloads.sourceforge.net/project/courier/${_srcname}/${pkgver}/${_srcname}-${pkgver}.tar.bz2)
sha512sums=('21e25a69516cfb330c1d9b5927db69487a31552346ccb1cb559ed65543da9dc7afd96c73ba8810961b09c3d4fdf3592e10de9d19bbca078ed7c2be7ef7e9fe52')
build() {
cd "${srcdir}/${_srcname}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc/courier \
--localstatedir=/var \
--mandir=/usr/share/man \
--with-db=gdbm \
--with-devel
make LDFLAGS+=-lstdc++
}
package() {
cd "${srcdir}/${_srcname}-${pkgver}"
make DESTDIR="${pkgdir}" install
chmod u+s "${pkgdir}/usr/bin/maildrop"
cd "${pkgdir}/usr/share/doc/maildrop/html"
for _files in *; do
install -Dm644 "${_files}" "${pkgdir}/usr/share/htmldoc/${_files}"
done
rm -rf "${pkgdir}/usr/share/maildrop"
}
|