PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>

pkgname=cozy-audiobooks-git
_gitname=cozy
pkgdesc='A modern audio book player for Linux and macOS using GTK+ 3'
pkgver=0.6.18.r1.g9d3d883
pkgrel=1
url='https://cozy.geigi.de'
arch=('i686' 'x86_64')
license=('GPL3')
provides=('cozy-audiobooks')
conflicts=('cozy-audiobooks')
depends=('appstream-glib'
         'desktop-file-utils'
         'gst-python'
         'gstreamer'
         'gtk3'
         'python-dbus'
         'python-distro'
         'python-requests'
         'python-pytz'
         'python-gobject'
         'python-mutagen'
         'python-cairo'
         'python-peewee'
         'gst-plugins-good')
makedepends=('meson' 'ninja' 'git')
source=("git+https://github.com/geigi/cozy")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/cozy"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${srcdir}/cozy"
  meson --prefix='/usr' build
  ninja -C build
  ninja -C build com.github.geigi.cozy-update-po
  ninja -C build extra-update-po
}

package() {
  cd "${srcdir}/cozy"
  DESTDIR="${pkgdir}" ninja -C build install
}