blob: a818373b4622ddcb8fcc7f69d8e8f48f6e38c4dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Ashar Khan <ashar786khan at gmail.com>
pkgname=cpeditor-git
_pkgname=cpeditor
pkgver=6.6.3.r14.g378b4a6
pkgrel=1
pkgdesc='The editor for competitive programming'
arch=('x86_64')
url='https://github.com/cpeditor/cpeditor'
license=('GPL3')
depends=('qt5-base>=5.15.0')
makedepends=(
"cmake"
"git"
"ninja"
"python3"
"qt5-tools"
)
optdepends=(
'cf-tool: submit to Codeforces support'
'clang: C++ format and language server support'
'jdk-openjdk: compile Java support'
'jre-openjdk: execute Java support'
'python: execute Python support'
'xterm: detached run support'
)
conflicts=("cpeditor")
source=('git://github.com/cpeditor/cpeditor.git'
'git://github.com/cpeditor/QCodeEditor.git'
'git://github.com/cpeditor/QtFindReplaceDialog.git'
'git://github.com/cpeditor/lsp-cpp.git'
'git://github.com/itay-grudev/singleapplication.git'
'git://github.com/MikeMirzayanov/testlib.git')
md5sums=('SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgname"
git submodule init
git config submodule.third_party/QCodeEditor.url "$srcdir/QCodeEditor"
git config submodule.third_party/QtFindReplaceDialog.url "$srcdir/QtFindReplaceDialog"
git config submodule.third_party/lsp-cpp.url "$srcdir/lsp-cpp"
git config submodule.third_party/singleapplication.url "$srcdir/singleapplication"
git config submodule.third_party/testlib.url "$srcdir/testlib"
git submodule update
}
build() {
cd "$_pkgname"
cmake -Bbuild -DCMAKE_INSTALL_PREFIX=/usr -DPORTABLE_VERSION=Off -DCMAKE_BUILD_TYPE=Release -GNinja
cmake --build build -j$(nproc)
}
package() {
cd "$_pkgname/build"
DESTDIR="$pkgdir/" ninja install
}
|