blob: be96ce2ef0eaa4e98a9d3d0f19b0078ff896aae2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_Name="CrealityPrint"
_pkgname="creality-print"
pkgname="${_pkgname}-bin"
pkgver=7.1.0.4414
_pkgver="${pkgver%.*}"
pkgrel=1
epoch=1
pkgdesc="3D slicer for Creality printers"
arch=(
'x86_64'
)
url="https://www.creality.com"
_url="https://github.com/CrealityOfficial/${_Name}"
license=(
'AGPL-3.0-only'
)
depends=(
'at-spi2-core'
'bzip2'
'cairo'
'dbus'
'expat'
'fontconfig'
'gdk-pixbuf2'
'glib2'
'glibc'
'gst-plugins-base-libs'
'gstreamer'
'gtk3'
'harfbuzz'
'libatomic'
'libdeflate'
'libgcc'
'libgl'
'libice'
'libsecret'
'libsm'
'libsoup3'
'libstdc++'
'libx11'
'libxext'
'nspr'
'nss'
'pango'
'sh'
'wayland'
'webkit2gtk-4.1'
'zlib'
'zstd'
)
makedepends=(
'patchelf'
)
optdepends=(
# 'python'
'slicer-udev: 3D printer connection rules'
)
provides=(
"${_pkgname}=${_pkgver}"
)
conflicts=(
"${_pkgname}"
)
_pkgsrc="${_pkgname}-${_pkgver}"
source=(
"${_pkgname}.sh"
"${_pkgsrc}-README.md::${_url}/raw/refs/tags/v${_pkgver}/README.md"
"${_pkgsrc}-LICENSE.txt::${_url}/raw/refs/tags/v${_pkgver}/LICENSE.txt"
)
source_x86_64=(
"${_url}/releases/download/v${_pkgver}/${_Name}_Ubuntu2404-V${pkgver}-x86_64-Release.AppImage"
)
sha256sums=('11c4dc922dfc686a051c2169549d8934ae1a0477fdf5c225860db08eb51a8fc1'
'a087787e8a3239bfbc0dc051565236dad4ff34ead1a3396c9cd17984fe898884'
'5537d2d539c94627446bf7eb30d30fda28d1de8aa9a41c25b83012db52ff6f8b')
sha256sums_x86_64=('0101b5578b26a81107cb20ce20d264779b95b8d630e042d0f6d3633ae37fed8f')
prepare() {
local source_array="source_${CARCH}[0]"
local source_url="${!source_array}"
local source_artifact="${source_url##*/}"
cd "${srcdir}"
chmod +x "${source_artifact}"
./"${source_artifact}" --appimage-extract > /dev/null
rm -rf "${source_artifact%.AppImage}"
mv -f "squashfs-root" "${source_artifact%.AppImage}"
cd "${source_artifact%.AppImage}"
sed -i "s/AppRun/${_Name}/g" "${_Name}.desktop"
patchelf --remove-rpath "bin/${_Name}"
patchelf --clear-execstack "bin/${_Name}"
}
package() {
local source_array="source_${CARCH}[0]"
local source_url="${!source_array}"
local source_artifact="${source_url##*/}"
cd "${srcdir}"
install -vDm755 "${_pkgname}.sh" "${pkgdir}/usr/bin/${_Name}"
install -vDm644 "${_pkgsrc}-README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "${_pkgsrc}-LICENSE.txt" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE.txt"
cd "${source_artifact%.AppImage}"
install -vDm644 "${_Name}.desktop" "${pkgdir}/usr/share/applications/${_Name}.desktop"
install -vDm644 "${_Name}.png" "${pkgdir}/usr/share/pixmaps/${_Name}.png"
install -vdm755 "${pkgdir}/opt/${_pkgname}"
cp -a --no-preserve=ownership -t "${pkgdir}/opt/${_pkgname}" "bin" "resources" "usr/lib"
}
|