blob: 58dca0e0af17c43091c2bf460764ddad8f5baafc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Contributor: Patrick McCarty <pnorcks at gmail dot com>
pkgname=createrepo_c
pkgver=0.13.0
pkgrel=1
pkgdesc="A C implementation of createrepo, a tool to create yum repositories"
arch=('i686' 'x86_64')
license=('GPL2')
url="https://github.com/rpm-software-management/$pkgname"
depends=('curl' 'drpm' 'glib2' 'libmodulemd>=2.3.0' 'libxml2'
'rpm-org' 'sqlite' 'zchunk' 'zlib')
makedepends=('bash-completion' 'cmake' 'doxygen'
'python' 'python-sphinx')
checkdepends=('python-nose')
optdepends=('python: for python bindings')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
md5sums=('38a191caf9737fdc0e7bdd5fcc148e23')
prepare() {
cd "$pkgname-$pkgver"
rm -rf build
mkdir build
}
build() {
cd "$pkgname-$pkgver"/build
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_FLAGS="$CFLAGS $CPPFLAGS" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_DESIRED=3 \
-DWITH_LIBMODULEMD=ON \
-DWITH_ZCHUNK=ON \
..
make VERBOSE=1
make doc
}
check() {
cd "$pkgname-$pkgver"/build
make tests
make ARGS="-V" test
}
package() {
cd "$pkgname-$pkgver"/build
make DESTDIR="$pkgdir/" install
if [[ $CARCH == x86_64 ]]; then
mv "$pkgdir/"usr/lib64/* "$pkgdir/"usr/lib
rmdir "$pkgdir/"usr/lib64
fi
install -Dp -m644 ../README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ft=sh ts=4 sw=4 noet:
|