blob: 532ecb517073c19488b3111c841e70ea64e2c4a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
_pkgname=cros-container-guest-tools
pkgname=${_pkgname}-git
pkgver=r44.45e9b92
pkgrel=1
pkgdesc="Guest tools for the Crostini containers on ChromeOS"
arch=('any')
license=('custom')
depends=()
optdepends=(
'xdg-utils: for setting default-web-browser to ChromeOS host via garcon bridge'
'xorg-apps: for XWayland functionality'
'wayland: for Wayland functionality'
)
install=cros-container-guest-tools.install
url="https://chromium.googlesource.com/chromiumos/containers/cros-container-guest-tools"
source=("git+${url}")
sha1sums=('SKIP')
pkgver() {
cd ${srcdir}/${_pkgname}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
# License
install -m644 -D ${srcdir}/${_pkgname}/LICENSE \
${pkgdir}/usr/share/licenses/cros-container-guest-tools/LICENSE
### cros-adapta -> included into cros-container-guest-tools.install
# After https://bugs.archlinux.org/task/58701 is fixed, will be done in PKGBUILD
#
# mkdir -p ${pkgdir}/usr/share/themes
# ln -sf /opt/google/cros-containers/cros-adapta \
# ${pkgdir}/usr/share/themes/CrosAdapta
### cros-apt-config -> not applicable
### cros-garcon
install -m755 -D ${srcdir}/${_pkgname}/cros-garcon/garcon-url-handler \
${pkgdir}/usr/bin/garcon-url-handler
install -m644 -D ${srcdir}/${_pkgname}/cros-garcon/garcon_host_browser.desktop \
${pkgdir}/usr/share/applications/garcon_host_browser.desktop
install -m644 -D ${srcdir}/${_pkgname}/cros-garcon/cros-garcon.service \
${pkgdir}/usr/lib/systemd/user/cros-garcon.service
install -m644 -D ${srcdir}/${_pkgname}/cros-garcon/cros-garcon-override.conf \
${pkgdir}/usr/lib/systemd/user/cros-garcon.service.d/cros-garcon-override.conf
### cros-guest-tools -> not applicable
### cros-sftp
install -m644 -D ${srcdir}/${_pkgname}/cros-sftp/cros-sftp.service \
${pkgdir}/usr/lib/systemd/system/cros-sftp.service
### cros-sommelier
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier/sommelierrc \
${pkgdir}/etc/sommelierrc
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier/sommelier.sh \
${pkgdir}/etc/profile.d/sommelier.sh
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier/sommelier@.service \
${pkgdir}/usr/lib/systemd/user/sommelier@.service
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier/sommelier-x@.service \
${pkgdir}/usr/lib/systemd/user/sommelier-x@.service
### cros-sommelier-config
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier-config/cros-sommelier-override.conf \
${pkgdir}/usr/lib/systemd/user/sommelier@0.service.d/cros-sommelier-override.conf
install -m644 -D ${srcdir}/${_pkgname}/cros-sommelier-config/cros-sommelier-x-override.conf \
${pkgdir}/usr/lib/systemd/user/sommelier-x@0.service.d/cros-sommelier-x-override.conf
### cros-sudo-config
install -m440 -D ${srcdir}/${_pkgname}/cros-sudo-config/10-cros-nopasswd \
${pkgdir}/etc/sudoers.d/10-cros-nopasswd
# replace sudo group with wheel group for no password sudo access
sed -i 's/%sudo/%wheel/1' ${pkgdir}/etc/sudoers.d/10-cros-nopasswd
### cros-systemd-overrides -> included into cros-container-guest-tools.install
### cross-ui-config
install -m644 -D ${srcdir}/${_pkgname}/cros-ui-config/gtkrc \
${pkgdir}/etc/gtk-2.0/gtkrc
install -m644 -D ${srcdir}/${_pkgname}/cros-ui-config/settings.ini \
${pkgdir}/etc/gtk-3.0/settings.ini
install -m644 -D ${srcdir}/${_pkgname}/cros-ui-config/01-cros-ui \
${pkgdir}/etc/dconf/db/local.d/01-cros-ui
install -m644 -D ${srcdir}/${_pkgname}/cros-ui-config/user \
${pkgdir}/etc/dconf/profile/user
install -m644 -D ${srcdir}/${_pkgname}/cros-ui-config/Trolltech.conf \
${pkgdir}/etc/xdg/Trolltech.conf
### cros-unattended-upgrades -> not applicable
### cros-wayland
install -m644 -D ${srcdir}/${_pkgname}/cros-wayland/10-cros-virtwl.rules \
${pkgdir}/usr/lib/udev/rules.d/10-cros-virtwl.rules
install -m644 -D ${srcdir}/${_pkgname}/cros-wayland/skel.weston.ini \
${pkgdir}/etc/skel/.config/weston.ini
}
|