blob: b0ecf9127fb9e1c856b54da0ee6a7d0e290975f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Maintainer: Julian Hofmann <aur at julianh dot de>
## links
# https://crossonic.org
# https://github.com/juho05/crossonic
_pkgname="crossonic"
pkgname="$_pkgname"
pkgver=0.4.0
pkgrel=1
pkgdesc="An OpenSubsonic compatible cross-platform music client"
arch=('x86_64')
url="https://github.com/juho05/crossonic"
license=("MPL-2.0")
depends=(
'gtk3'
'mpv'
'libayatana-appindicator'
'fontconfig'
'cairo'
'glib2'
'glibc'
'gcc-libs'
'at-spi2-core'
'pango'
'libepoxy'
)
makedepends=(
'clang'
'cmake'
'fvm'
'git'
'ninja'
'patchelf'
)
options=('!lto')
_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=(
"$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext"
)
sha256sums=(
'ea40d751e181c95508b82914746c12d1815e470bd46396d79874e25c67ab902a'
)
prepare() {
cd "$_pkgsrc"
export FVM_CACHE_PATH="$SRCDEST/fvm-cache"
: ${_fvm_version=$(grep 'FLUTTER_VERSION: ' .github/workflows/release.yml | cut -d'"' -f2)}
fvm install "$_fvm_version"
fvm use "$_fvm_version" --force
fvm flutter --disable-analytics
fvm flutter --no-version-check pub get
fvm dart run build_runner build
}
build() {
export CFLAGS CXXFLAGS
CFLAGS+=" -Wno-deprecated-declarations"
CXXFLAGS+=" -Wno-deprecated-declarations"
export FVM_CACHE_PATH="$SRCDEST/fvm-cache"
cd "$_pkgsrc"
fvm flutter build linux --no-pub --release --dart-define=VERSION_CHECK=false
}
package() {
cd "$_pkgsrc"
pushd build/linux/x64/release
install -Dm755 "bundle/Crossonic" "${pkgdir}/usr/lib/${_pkgname}/crossonic"
cmake -DCMAKE_INSTALL_PREFIX="${pkgdir}/usr/lib/${_pkgname}" .
cmake -P cmake_install.cmake
popd
patchelf --set-rpath '$ORIGIN' "$pkgdir/usr/lib/$_pkgname/lib"/*.so
install -dm755 "$pkgdir/usr/bin"
ln -s "/usr/lib/$_pkgname/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dm644 "assets/icon/desktop/crossonic-512.png" "$pkgdir/usr/share/pixmaps/$_pkgname.png"
install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/org.crossonic.app.desktop" << END
[Desktop Entry]
Type=Application
Name=Crossonic
Comment=$pkgdesc
Exec=$_pkgname
Icon=$_pkgname
SingleMainWindow=true
StartupWMClass=org.crossonic.app
Terminal=false
Categories=Multimedia
END
}
|