blob: 9f43690362f1da6fb5ef607743cd884401e01739 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: ByteDream
pkgname=crunchy-cli-bin
pkgdesc="Command-line downloader for Crunchyroll"
arch=('x86_64' 'aarch64')
url="https://github.com/crunchy-labs/crunchy-cli"
license=('MIT')
pkgver=3.6.6
pkgrel=1
depends=('ffmpeg')
provides=('crunchy-cli')
conflicts=('crunchy-cli')
source_x86_64=(
"crunchy-cli::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-linux-x86_64"
"manpages.zip::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-manpages.zip"
"completions.zip::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-completions.zip"
"LICENSE::https://raw.githubusercontent.com/crunchy-labs/crunchy-cli/v${pkgver}/LICENSE"
)
source_aarch64=(
"crunchy-cli::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-linux-aarch64"
"manpages.zip::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-manpages.zip"
"completions.zip::https://github.com/crunchy-labs/crunchy-cli/releases/download/v${pkgver}/crunchy-cli-v${pkgver}-completions.zip"
"LICENSE::https://raw.githubusercontent.com/crunchy-labs/crunchy-cli/v${pkgver}/LICENSE"
)
noextract=("manpages.zip" "completions.zip")
sha256sums_x86_64=('d75de9e8e8d3ec6466265911f2da60cd380c0eaf12b69bc1271a64c1dbba8742' '5515365c240095aa4364f6f88446dfcf2407bf6073fcb168a20b7eb53d057615' '0f3fb002b9014e143a106d1054d4c548fbc0a9efbf5c35c561d5c743fd8796b5' '4a5c6b7d6d7e0948869cfc1f92029dbb7503f80cd23878531f6285214e31ea24')
sha256sums_aarch64=('62438850669906db053899254a7c5bf3c759bb2c81e3650cd95b52bd8f67cc99' '5515365c240095aa4364f6f88446dfcf2407bf6073fcb168a20b7eb53d057615' '0f3fb002b9014e143a106d1054d4c548fbc0a9efbf5c35c561d5c743fd8796b5' '4a5c6b7d6d7e0948869cfc1f92029dbb7503f80cd23878531f6285214e31ea24')
package() {
cd "$srcdir"
# all files in manpages.zip and completions.zip are stored in root of the archive, makepkg extracts them all to $srcdir
# which makes it pretty messy. so the extraction is done manually to keep the content of $srcdir structured
mkdir manpages completions
cd manpages
bsdtar -xf ../manpages.zip
cd ../completions
bsdtar -xf ../completions.zip
cd ..
install -Dm755 crunchy-cli $pkgdir/usr/bin/crunchy-cli
install -Dm644 manpages/* -t $pkgdir/usr/share/man/man1
install -Dm644 completions/crunchy-cli.bash $pkgdir/usr/share/bash-completion/completions/crunchy-cli
install -Dm644 completions/_crunchy-cli $pkgdir/usr/share/zsh/site-functions/_crunchy-cli
install -Dm644 completions/crunchy-cli.fish $pkgdir/usr/share/fish/vendor_completions.d/crunchy-cli.fish
install -Dm644 LICENSE $pkgdir/usr/share/licenses/crunchy-cli/LICENSE
}
|