blob: 6fb95562d7cdd0c82b2947237d33f3892bfdd0c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
# Contributor: Giovanni Harting <539@idlegandalf.com>
pkgname=cryptpad
pkgver=3.19.1
pkgrel=1
pkgdesc="Realtime collaborative visual editor with zero knowlege server"
arch=('any')
url="https://github.com/xwiki-labs/cryptpad"
license=('AGPL3')
depends=('nodejs')
makedepends=('npm' 'bower' 'git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/xwiki-labs/cryptpad/archive/$pkgver.tar.gz"
"cryptpad.service"
"cryptpad.sysusers"
"cryptpad.tmpfiles")
sha256sums=('b706baf1ee7d948eb549b7ba4f9270188e7dde067f4e92b7c3162e5907c50af6'
'522851fbe4e0e41fd6ece8b2b0ed17bbae0233a58328b7994a5207aa341a635b'
'999a271d64b75c7c447fdb21486b27463c04679677e57ea9551a3b0429c618f6'
'fa710a977248c1cd2482d4624325d3f8ac8479c9d748dd636077f55f48906d44')
package() {
cd "$pkgname-$pkgver"
npm install -g --user root --prefix "${pkgdir}"/usr --cache "${srcdir}/npm-cache"
bower install --allow-root
rm -r "${pkgdir}"/usr
# make sure directory permissions are acceptable
find . -type d -exec chmod 755 {} +
# Documentation
install -t "$pkgdir/usr/share/doc/$pkgname" -Dm 644 docs/{ARCHITECTURE.md,example.nginx.conf} CHANGELOG.md
# Cryptpad
install -Dt "$pkgdir/usr/share/$pkgname" package.json server.js
cp -rt "$pkgdir/usr/share/$pkgname" customize.dist lib node_modules scripts www
# Config
sed -e "s|\(Path: '\)\./|\1/var/lib/cryptpad/|" \
-e "s|'/var/lib/cryptpad/data/logs'|false|" \
-e "s|logToStdout: false|logToStdout: true|" \
-i config/config.example.js
install -Dm 644 config/config.example.js "${pkgdir}/etc/webapps/$pkgname/config.example.js"
ln -s "../../../etc/webapps/$pkgname" "$pkgdir/usr/share/$pkgname/config"
# systemd
install -Dm 644 "${srcdir}"/cryptpad.sysusers "${pkgdir}"/usr/lib/sysusers.d/cryptpad.conf
install -Dm 644 "${srcdir}"/cryptpad.service "${pkgdir}"/usr/lib/systemd/system/cryptpad.service
install -Dm 644 "${srcdir}"/cryptpad.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/cryptpad.conf
}
|