PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Michael Hupf <michihupf at protonmail dot com>
_pkgname=cs-demo-manager
pkgname=$_pkgname-appimage
pkgver=3.20.1
pkgrel=1
pkgdesc="Companion application for Counter-Strike demos."
arch=('any')
url="https://cs-demo-manager.com/"
license=('MIT')
depends=('postgresql')
options=('!strip')
_appimage="CS-Demo-Manager-$pkgver.AppImage"
noextract=("$_appimage")
source=("$_appimage::https://github.com/akiver/$_pkgname/releases/download/v$pkgver/$_appimage"
    "AKIVER_LICENSE::https://raw.githubusercontent.com/akiver/$_pkgname/refs/tags/v$pkgver/LICENSE"
    )
sha256sums=('95608b6c4aa28d0328a0212bebe0b2ee1989b215e817bb7b8d0042a2655c5115'
            '13c63653c5aab89a5515ebb31b6c1dd518006cf7bd8d30e157007ab04aee1f93')

prepare() {
    chmod +x "$_appimage"
    ./"$_appimage" --appimage-extract
}

build() {
    # Adjust .desktop so it will work outside of AppImage container
    sed -i -E "s|AppRun|/usr/bin/$_pkgname|"\
        "squashfs-root/$_pkgname.desktop"
    # Fix permissions; .AppImage permissions are 700 for all directories
    chmod -R a-x+rX squashfs-root/usr
}

package() {
    # AppImage
    install -Dm755 "$srcdir/$_appimage" "$pkgdir/opt/$pkgname/$pkgname.AppImage"

    # Desktop file
    install -Dm644 "$srcdir/squashfs-root/$_pkgname.desktop"\
            "$pkgdir/usr/share/applications/$_pkgname.desktop"

    # Icon images
    install -dm755 "$pkgdir/usr/share/"
    cp -a "$srcdir/squashfs-root/usr/share/icons" "$pkgdir/usr/share/"

    # Symlink image
    install -dm755 "$pkgdir/usr/bin"
    ln -s "/opt/$pkgname/$pkgname.AppImage" "$pkgdir/usr/bin/$_pkgname"

    # Licenses
    install -Dm644 "$srcdir/AKIVER_LICENSE"\
        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 "$srcdir/squashfs-root/LICENSE.electron.txt"\
        "$pkgdir/usr/share/licenses/$pkgname/LICENSE.electron.txt"
    install -Dm644 "$srcdir/squashfs-root/LICENSES.chromium.html"\
        "$pkgdir/usr/share/licenses/$pkgname/LICENSES.chromium.html"
}