PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Mohammad Reza Karmi <m.r.karimi.j@gmail.com>

pkgname=css-inline
pkgver=0.20.0
pkgrel=1
pkgdesc="High-performance library for inlining CSS into HTML 'style' attributes"
arch=('x86_64' 'aarch64')
url="https://github.com/Stranger6667/css-inline"
license=('MIT')
depends=(gcc-libs glibc)
makedepends=(rust git)
source=("$pkgname::git+$url#tag=rust-v$pkgver")
b2sums=('c323d24ec7d16a9d96e22834777cb1fbe427a2c79e3c14e57b78f87c81da2ec261d0dc846d748dc7e041549acdf284c869aa3e5732289580a706a1f2563a7185')

prepare() {
    cd "$pkgname/css-inline"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --target host-tuple
}

build() {
    cd "$pkgname/css-inline"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    export CFLAGS="$CFLAGS -ffat-lto-objects"
    cargo build --frozen --release --all-features
}

check() {
    cd "$pkgname/css-inline"

    export RUSTUP_TOOLCHAIN=stable
    python tests/server.py &
    local _server_pid=$!
    cargo test --frozen --release --all-features
    kill $_server_pid
}

package() {
    cd "$pkgname/css-inline"

    install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
    install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname/LICENSE" ../LICENSE
}