blob: 71970fbb00c19daf6c5c586e3a16c415ceb1c750 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="cunicu"
pkgver=0.6.0
pkgrel=1
pkgdesc="A zeroconf peer-to-peer mesh VPN using Wireguard® and Interactive Connectivity Establishment (ICE)"
arch=('x86_64' 'aarch64' 'i686' 'armv7h')
url="https://cunicu.li"
# _url="https://github.com/${pkgname}/${pkgname}"
_url="https://codeberg.org/${pkgname}/${pkgname}"
license=('Apache-2.0')
depends=('gcc-libs' 'glibc')
makedepends=('git' 'go' 'protoc-gen-go' 'protoc-gen-go-grpc')
optdepends=('wireguard-tools: for controlling WireGuard interfaces')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}::git+${_url}.git#tag=v${pkgver}")
b2sums=('27ec5fe4ff845cb1867eb1af8c881580b030d8ed30e0eb06076ae8060f1efa249073e77d186f0bf552a5274a09086d3de27f7f740e2d934290bb36e270276911')
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build" "completions" "manpages"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${pkgname}" -ldflags "\
-X ${url#https://}/${pkgname}/pkg/buildinfo.Version=${pkgver} \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Tag=$(git describe --tags) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Commit=$(git rev-parse HEAD) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Branch=$(git rev-parse --abbrev-ref HEAD) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.DateStr=$(date -Iseconds)" \
./"cmd/${pkgname}"
for _sh in bash fish zsh powershell; do
./"build/${pkgname}" completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
./"build/${pkgname}" docs man > "manpages/${pkgname}.1"
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -vDm644 "manpages/${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
cd "${srcdir}/${_pkgsrc}/completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
cd "${srcdir}/${_pkgsrc}/etc"
install -vDm644 "${pkgname}.yaml" "${pkgdir}/etc/${pkgname}.example.yaml"
cd "${srcdir}/${_pkgsrc}/etc/systemd"
install -vDm644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/${pkgname}.service"
}
|