blob: ede843645dc33a7687aa6c18c7aa237e17f14e12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="cunicu"
pkgver=0.5.13
pkgrel=1
pkgdesc="A zeroconf peer-to-peer mesh VPN using Wireguard® and Interactive Connectivity Establishment (ICE)"
arch=('any')
url="https://${pkgname}.li"
# _url="https://github.com/${pkgname}/${pkgname}"
_url="https://codeberg.org/${pkgname}/${pkgname}"
license=('Apache-2.0')
depends=('glibc' 'gcc-libs')
makedepends=('git' 'go' 'protoc-gen-go' 'protoc-gen-go-grpc') # 'make' 'golangci-lint'
# checkdepends=('ginkgo')
optdepends=('bash-completion: for auto-completion'
'zsh-completions: for auto-completion'
'wireguard-tools: for controlling WireGuard interfaces')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}::git+${_url}/#tag=v${pkgver}")
sha256sums=('5c613f556293c936918172047a732d0b735ec2fdfa6bfb2f57a6d7f69ef97aa0')
prepare() {
cd "${srcdir}/${_pkgsrc}"
# make prepare
mkdir -p "build" "completions" "manpages"
go mod tidy
go generate ./...
go mod download
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
# make
go build -o "build/${pkgname}" -ldflags "\
-X ${url#https://}/${pkgname}/pkg/buildinfo.Version=${pkgver} \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Tag=$(git describe --tags) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Commit=$(git rev-parse HEAD) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.Branch=$(git rev-parse --abbrev-ref HEAD) \
-X ${url#https://}/${pkgname}/pkg/buildinfo.DateStr=$(date -Iseconds)" \
./"cmd/${pkgname}"
# make completions
for _sh in bash fish zsh powershell; do
./"build/${pkgname}" completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
# make docs
./"build/${pkgname}" docs man > "manpages/${pkgname}.1"
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# # make tests
#
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -Dm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "manpages/${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
cd "completions"
install -Dm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -Dm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -Dm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
install -Dm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
}
|