blob: f6e8979e2a76a6447ce029578dc50579d469dd10 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
|
# Maintainer: AugusDogus <augie@linux.com>
pkgname=cursor-early-access-bin
pkgver=3.19.13
_upstream_pkgver=3.19.13
pkgrel=1
pkgdesc='AI-first coding environment (early access channel, bundled Electron)'
arch=('x86_64' 'aarch64')
url="https://www.cursor.com"
license=('LicenseRef-Cursor_EULA')
provides=('cursor')
conflicts=('cursor-bin' 'cursor-nightly-bin' 'cursor-ide-bin')
depends=(
'alsa-lib'
'dbus'
'gcc-libs'
'gtk3'
'libdrm'
'libsecret'
'libxkbfile'
'mesa'
'nss'
'xdg-utils'
)
optdepends=(
'libnotify: desktop notifications'
'org.freedesktop.secrets: credential storage via SecretService'
'libdbusmenu-glib: KDE global menu support'
)
options=(!strip !debug)
_commit=dd066f332fcea7382764400fde902f61920648d5
source_x86_64=(
"cursor_${_upstream_pkgver}_amd64.deb::https://downloads.cursor.com/production/${_commit}/linux/x64/deb/amd64/deb/cursor_${_upstream_pkgver}_amd64.deb"
)
source_aarch64=(
"cursor_${_upstream_pkgver}_arm64.deb::https://downloads.cursor.com/production/${_commit}/linux/arm64/deb/arm64/deb/cursor_${_upstream_pkgver}_arm64.deb"
)
source=(
cursor.desktop
cursor-launcher.sh
)
sha512sums_x86_64=('SKIP')
sha512sums_aarch64=('SKIP')
sha512sums=(
'037aa5d878eddb06fc1d5be788e7bc64545773decacb34228053be746dfc33237371ad49cc331dac8e3437d7d885a9bc1564d0f114fc22e308827b33d0c55ad8'
'9defecd35fd033a484642732605264cc00faf5791d852234d9705bf9ac005c76173780cd496208e4150685ac9ddbb73c8eb87cd5141526dd4521d455342e8233')
sha512sums_x86_64[0]=3c952035fa1809caded7059b7addbb01a9143cd248ecff27cdb3cb3af47d4bc824ed60dfd9757e105a342e53280e075d81f775790295a3272818bab5a994b305
sha512sums_aarch64[0]=b917c69bff9f16173835ca6045c3b784b383f6143e2d79e72967c1977fa4cf1b0e03570531debc2fae0beab0f69e660dcf888f021ed60569a8dc5412cf3cefbb
noextract=(
"cursor_${_upstream_pkgver}_amd64.deb"
"cursor_${_upstream_pkgver}_arm64.deb"
)
package() {
case "$CARCH" in
x86_64) _deb="cursor_${_upstream_pkgver}_amd64.deb" ;;
aarch64) _deb="cursor_${_upstream_pkgver}_arm64.deb" ;;
esac
# Extract full deb — keep bundled Electron intact.
bsdtar -xOf "$_deb" data.tar.xz |
tar -xJf - -C "$pkgdir"
# Fix zsh completion path for Arch
if [[ -d "$pkgdir/usr/share/zsh/vendor-completions" ]]; then
mv "$pkgdir/usr/share/zsh/vendor-completions" \
"$pkgdir/usr/share/zsh/site-functions"
fi
install -Dm644 "$srcdir/cursor.desktop" \
"$pkgdir/usr/share/applications/cursor.desktop"
install -Dm755 "$srcdir/cursor-launcher.sh" "$pkgdir/usr/bin/cursor"
_license="$pkgdir/usr/share/cursor/resources/app/LICENSE.txt"
if [[ ! -f "$_license" ]]; then
_license=$(find "$pkgdir/usr/share/cursor" -maxdepth 8 -type f \( -name 'LICENSE.txt' -o -name 'LICENSE' \) -print -quit 2>/dev/null)
fi
if [[ -f "$_license" ]]; then
install -Dm644 "$_license" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
else
echo "Warning: Cursor license file not found in .deb; skipping /usr/share/licenses install" >&2
fi
if [[ -f "$pkgdir/usr/share/cursor/chrome-sandbox" ]]; then
chmod 4755 "$pkgdir/usr/share/cursor/chrome-sandbox"
fi
}
|