blob: 92ae6dda7497f778ee8ad46798200befb77bd549 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: archlinux.info:tdy
pkgbase=cutechess
pkgname=(cutechess cutechess-cli libcutechess libcutechess-docs)
pkgver=0.9.4
pkgrel=2
pkgdesc="Tools for working with chess engines"
arch=(i686 x86_64)
url=http://cutechess.com
license=(GPL3)
depends=(qt5-svg)
makedepends=(doxygen)
source=(https://github.com/$pkgname/$pkgname/archive/gui-$pkgver.tar.gz)
sha256sums=(315676ce661729e9acabb741ab538196ae85019efab4e3f9e4a08c3410580af8)
prepare() {
cd $pkgbase-gui-$pkgver/projects
sed -n '2,23s:^[ ]*::p' gui/components/pgnhighlighter/src/pgnhighlighter.h > COPYING.gui
sed -n '2,23s:^[ ]*::p' lib/components/json/src/jsonparser.h > COPYING.lib
}
build() {
cd $pkgbase-gui-$pkgver
qmake
make
}
package_cutechess() {
pkgdesc="A graphical interface for chess"
license=(GPL3 MIT)
cd $pkgbase-gui-$pkgver/projects
install -Dm755 gui/$pkgname "$pkgdir"/usr/bin/$pkgname
install -Dm644 COPYING.gui "$pkgdir"/usr/share/licenses/$pkgname/COPYING
install -Dm644 gui/res/icons/${pkgname}_32x32.xpm \
"$pkgdir"/usr/share/pixmaps/${pkgname}_32x32.xpm
install -Dm644 ../dist/linux/$pkgname.desktop \
"$pkgdir"/usr/share/applications/$pkgname.desktop
}
package_cutechess-cli() {
pkgdesc="A command-line tool to automate chess engine tournaments"
depends=(qt5-base)
cd $pkgbase-gui-$pkgver
install -Dm755 projects/cli/$pkgname "$pkgdir"/usr/bin/$pkgname
install -Dm644 docs/$pkgname.6 "$pkgdir"/usr/share/man/man6/$pkgname.6
install -Dm644 docs/engines.json.5 "$pkgdir"/usr/share/man/man5/engines.json.5
}
package_libcutechess() {
pkgdesc="A static library for chess"
license=(GPL3 MIT)
depends=()
options=(staticlibs)
cd $pkgbase-gui-$pkgver/projects
install -Dm644 lib/$pkgname.a "$pkgdir"/usr/lib/$pkgname.a
install -Dm644 COPYING.lib "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
package_libcutechess-docs() {
pkgdesc="API documentation for libcutechess"
arch=(any)
depends=()
options=(docs)
cd $pkgbase-gui-$pkgver
make doc-api
install -dm755 "$pkgdir"/usr/share/doc/${pkgname%-*}/html/
install -m644 docs/api/html/* "$pkgdir"/usr/share/doc/${pkgname%-*}/html/
sed -i "s:$srcdir/$pkgbase-gui-$pkgver/docs/api:/usr/share/${pkgname%-*}/html:g" \
-s "$pkgdir"/usr/share/doc/${pkgname%-*}/html/*.html
}
|