blob: 763b80bd040a07b1d16c17de70e50055b143b315 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: archlinux.info:tdy
pkgbase=cutechess-git
pkgname=(cutechess-git cutechess-cli-git libcutechess-git libcutechess-git-docs)
pkgver=r1878.8d265fe
pkgrel=2
pkgdesc="Tools for working with chess engines"
arch=(i686 x86_64)
url=http://cutechess.com
license=(GPL3)
depends=(qt5-svg)
makedepends=(git doxygen)
source=($pkgbase::git+https://github.com/${pkgbase%-git}/${pkgbase/-/.})
sha256sums=(SKIP)
pkgver() {
cd $pkgbase
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $pkgbase/projects
sed -n '2,23s:^[ ]*::p' gui/components/pgnhighlighter/src/pgnhighlighter.h > COPYING.gui
sed -n '2,23s:^[ ]*::p' lib/components/json/src/jsonparser.h > COPYING.lib
}
build() {
cd $pkgbase
qmake
make
}
package_cutechess-git() {
pkgdesc="A graphical interface for chess"
license=(GPL3 MIT)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
cd $pkgbase/projects
install -Dm755 gui/${pkgname%-git} "$pkgdir"/usr/bin/${pkgname%-git}
install -Dm644 COPYING.gui "$pkgdir"/usr/share/licenses/$pkgname/COPYING
install -Dm644 gui/res/icons/${pkgbase%-git}_32x32.xpm \
"$pkgdir"/usr/share/pixmaps/${pkgbase%-git}_32x32.xpm
install -Dm644 ../dist/linux/${pkgbase%-git}.desktop \
"$pkgdir"/usr/share/applications/${pkgbase%-git}.desktop
}
package_cutechess-cli-git() {
pkgdesc="A command-line tool to automate chess engine tournaments"
depends=(qt5-base)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
cd $pkgbase
install -Dm755 projects/cli/${pkgname%-git} "$pkgdir"/usr/bin/${pkgname%-git}
install -Dm644 docs/${pkgname%-git}.6 "$pkgdir"/usr/share/man/man6/${pkgname%-git}.6
install -Dm644 docs/engines.json.5 "$pkgdir"/usr/share/man/man5/engines.json.5
}
package_libcutechess-git() {
pkgdesc="A static library for chess"
license=(GPL3 MIT)
depends=()
options=(staticlibs)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
cd $pkgbase/projects
install -Dm644 lib/${pkgname%-git}.a "$pkgdir"/usr/lib/${pkgname%-git}.a
install -Dm644 COPYING.lib "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
package_libcutechess-git-docs() {
pkgdesc="API documentation for libcutechess"
arch=(any)
depends=()
options=(docs)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
cd $pkgbase
make doc-api
install -dm755 "$pkgdir"/usr/share/doc/libcutechess/html/
install -m644 docs/api/html/* "$pkgdir"/usr/share/doc/libcutechess/html/
sed -i "s:$srcdir/$pkgbase/docs/api:/usr/share/libcutechess/html:g" \
-s "$pkgdir"/usr/share/doc/libcutechess/html/*.html
}
|