summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c51b7c5e163ef9dd493a9a90d331ae2b5df311a9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: lithm <lithm at posteo dot de>
pkgname=cutedscapture-git
_binname=CuteDSCapture
pkgver=1.0.r12.g4e7d453
pkgrel=1
pkgdesc="A DS capture software"
arch=('i686' 'x86_64')
url="https://github.com/Gotos/CuteDSCapture"
license=('unknown')
depends=('sfml' 'libusb')
makedepends=('git')
provides=('cutedscapture')
conflicts=('cutedscapture')
backup=('etc/udev/rules.d/95-dscapture.rules')
install="${pkgname}.install"
source=("${pkgname}::git+https://github.com/Gotos/CuteDSCapture.git")
md5sums=('SKIP')


pkgver() {
    cd "${srcdir}/${pkgname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${pkgname}"
    ./autogen.sh
    ./configure
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    install -D -m755 "${_binname}" "${pkgdir}/usr/bin/${_binname}"
    install -D -m644 "95-dscapture.rules" "${pkgdir}/etc/udev/rules.d/95-dscapture.rules"
}