summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a147d79eb2d80c23975d3c840e54bacf935344ea (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=cutefish-qt-plugins
pkgver=0.5
pkgrel=5
pkgdesc="Unify Qt application style of CutefishOS"
arch=('x86_64')
url="https://github.com/cutefishos/qt-plugins"
license=('GPL-3.0-or-later')
groups=('cutefish')
depends=('kwindowsystem5' 'libdbusmenu-qt5' 'libqt5xdg' 'qt5-quickcontrols2')
makedepends=('extra-cmake-modules' 'ninja' 'qt5-tools')
source=("https://github.com/cutefishos/qt-plugins/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('ac1e614d41e202cc94125dc5862d8d31b746daa1f1509a775b3e7c084b815f284f1dbd221337b784af0488c50c832af25f4ee0951739fc1e4549e511638d0a95')

prepare() {
  cd qt-plugins-$pkgver
  # A version for ECM is necessary to make it work. Pick a random version here.
  sed -i -r '/include\(ECMQueryQmake\)/i find_package(ECM 5.26)' widgetstyle/CMakeLists.txt
}

build() {
  cmake -G Ninja -B build -S qt-plugins-$pkgver \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}