blob: 8a75f7b558a917274999c4a783cfa9c50803e5a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_pkgname="cxcli"
pkgname="${_pkgname}-git"
pkgver=1.225.1.r0.g5958e4e
pkgrel=1
pkgdesc="The missing CLI for your Dialogflow CX projects"
arch=('any')
url="https://${_pkgname}.xavidop.me"
_url="https://github.com/xavidop/dialogflow-cx-cli"
license=('Apache-2.0')
makedepends=('git' 'go')
depends=('glibc')
optdepends=('bash-completion: for shell auto-completion'
'zsh-completions: for shell auto-completion')
provides=("dialogflow-cx-cli=${pkgver%%.r*}")
conflicts=('dialogflow-cx-cli')
_pkgsrc="dialogflow-cx-cli"
source=("${_pkgsrc}::git+${_url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgsrc}"
git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build" "completions" "manpages"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${_pkgname}" .
# ./"scripts/manpages.sh"
./"build/${_pkgname}" man > "manpages/${_pkgname}.1"
#./"scripts/completions.sh"
for _sh in bash fish zsh powershell; do
./"build/${_pkgname}" completion "${_sh}" > "completions/${_pkgname}.${_sh}"
done
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -Dm755 "build/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -Dm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE.md"
install -Dm644 "manpages/${_pkgname}.1" "${pkgdir}/usr/share/man/man1/${_pkgname}.1"
cd "completions"
install -Dm644 "${_pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
install -Dm644 "${_pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
install -Dm644 "${_pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
install -Dm644 "${_pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${_pkgname}.ps1"
}
|