blob: 4cdcf24cc34dd1ae6be143a4635ac131cb0563f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Peter Justin <peter.justin@outlook.com>
pkgname=d2rloader
pkgver=1.6.2
pkgrel=1
pkgdesc="Cross-platform Diablo 2 Resurrected Loader written in Python/Qt"
arch=('any')
url="https://github.com/sh4nks/d2rloader"
license=('MIT')
depends=(
'pyside6'
'python-psutil'
'python-pydantic'
'python-unidecode'
'python-loguru'
'python-pluggy'
'umu-launcher'
'wmctrl'
)
optdepends=(
'gamemode: use gamemode to run D2R instances'
)
provides=("d2rloader")
conflicts=("d2rloader")
makedepends=('python-hatch' 'python-installer')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/sh4nks/d2rloader/archive/v${pkgver}.tar.gz")
sha256sums=('22c76ab3396110235f59305deabb306fe2748113acb79ac0f8aeeb58dff36c71')
prepare() {
cd "$pkgname-$pkgver"
wheels=$(ls dist/*.whl 2> /dev/null | wc -l)
if [ "$wheels" != "0" ]; then
rm dist/*.whl;
fi
}
build() {
cd "$pkgname-$pkgver"
hatch build
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
# link app icons to system folder
for res in 256x256 128x128 64x64 48x48 32x32 16x16; do
install -dm755 "${pkgdir}"/usr/share/icons/hicolor/${res}/apps
install -Dm644 "./resources/icons/${res}/d2rloader.png" "${pkgdir}"/usr/share/icons/hicolor/${res}/apps/d2rloader.png
done
install -dm755 "$pkgdir/usr/share/applications"
install -Dm644 './resources/d2rloader.desktop' "$pkgdir/usr/share/applications/d2rloader.desktop"
install -dm755 "$pkgdir/usr/bin"
install -Dm755 "./resources/bin/d2rloader" "$pkgdir/usr/bin/d2rloader"
}
|