PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=d2vwitch-git
pkgver=v3.3.gbd0b13b
pkgrel=1
pkgdesc="Cross-platform D2V creator. (GIT version)"
arch=('x86_64')
url='http://forum.doom9.org/showthread.php?t=173090'
license=('LGPL2.1' 'ISC')
depends=('vapoursynth'
         'libavutil.so'
         'libavformat.so'
         'libavcodec.so'
         'gcc-libs'
         'qt5-base'
         'xdg-utils'
         )
makedepends=('git'
             'meson'
             )
provides=('d2vwitch')
conflicts=('d2vwitch')
source=('d2vwitch::git+https://github.com/dubhater/D2VWitch.git'
        'd2vwitch.desktop'
        'd2vwitch.png'
        )
sha256sums=('SKIP'
            '6d9204fc7dab73b19976241ce5a4e74fed5c3d264796b782c02d783dd8f1bbb0'
            'c63a756f6e375ef4a6f220fcdde3f4a05f7a101c0c0dc3743ce9207730719bd5'
            )

pkgver() {
  cd d2vwitch
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  arch-meson ../d2vwitch \
    --libdir /usr/lib/vapoursynth

  LC_ALL=C ninja
}

package(){
  DESTDIR="${pkgdir}" ninja -C build install

  install -Dm644 "${srcdir}/d2vwitch.desktop" "${pkgdir}/usr/share/applications/d2vwitch.desktop"
  install -Dm644 "${srcdir}/d2vwitch.png" "${pkgdir}/usr/share/pixmaps/d2vwitch.png"

  install -d "${pkgdir}/usr/share/licenses/${pkgname}"
  head -n+16 d2vwitch/src/Audio.cpp | tail -n 15 > "${pkgdir}/usr/share/licenses/${pkgname}/ISC"
}