blob: e7660bd431bf4816e1fdc4031b95c016f85d15ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Jeremy Symon <jtsymon@gmail.com>
pkgname=dale-git
_gitname=dale
pkgver=r1040.24457a1
pkgrel=1
pkgdesc='Lisp-flavoured C'
url='https://github.com/tomhrr/dale/'
arch=('x86_64' 'i686')
license=('BSD')
depends=('libffi' 'zlib' 'gcc-libs-multilib' 'ncurses')
makedepends=('git' 'cmake' 'pkg-config' 'llvm35')
provides=('dale')
source=(
"git+https://github.com/tomhrr/${_gitname}.git"
)
sha512sums=(
'SKIP'
)
pkgver() {
cd "$_gitname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
mkdir -p build
cd build
cmake ../$_gitname -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_MANDIR=/usr/share/man
make
}
check() {
cd build
make tests
}
package() {
cd build
make DESTDIR="$pkgdir" install
cd ../$_gitname
install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|