blob: 8f5ee4ebc506562bbb2e6121fe69426be090638a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Marcin Wieczorek <marcin@marcin.co>
# Contributor: Stefan J. Betz <info@stefan-betz.net>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Aaron Schaefer <aaron@elasticdog.com>
# Contributor: N. I. - izmntuk
pkgname=dar
pkgver=2.7.14
pkgrel=1
pkgdesc='A full featured command-line backup tool, short for Disk ARchive'
arch=('i686' 'x86_64')
url='http://dar.linux.free.fr/'
license=('GPL')
depends=('libgcrypt' 'zlib' 'lzo' 'bzip2' 'xz' 'attr' 'argon2' 'libthreadar')
optdepends=('perl: for running some samples'
'librsync: for delta binary')
makedepends=('doxygen')
source=("http://downloads.sourceforge.net/project/dar/dar/${pkgver}/dar-${pkgver}.tar.gz")
sha512sums=('0436c67e0dbd8f5e96e01a0db48a469d80fb81a7c7f37aed98308bd55d60d699b21c755d95fa83891690231fd2510eaa6c6652fb99a1bad9c8210084031391d4')
backup=('etc/darrc')
options=('!libtool')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
## --enable-threadar: EXPERIMENTAL multithread support
if [[ "${CARCH}" == i686 ]]; then
EXTRA_OPTIONS="--enable-mode=32"
fi
./configure --prefix=/usr --sysconfdir=/etc \
--disable-dar-static \
--disable-static \
--disable-upx \
--disable-build-html \
${EXTRA_OPTIONS}
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" pkgdatadir="/usr/share/doc/${pkgname}/html" install
install -d "${pkgdir}/usr/share/doc/${pkgname}"
install -pm644 AUTHORS ChangeLog NEWS README THANKS TODO \
"${pkgdir}/usr/share/doc/${pkgname}"
rm -rf "${pkgdir}/usr/share/doc/dar/html/man"
}
|