blob: 226bf66db1a30d59cc3fea618186c6c13e1e20ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Marcin Wieczorek <marcin@marcin.co>
# Contributor: Stefan J. Betz <info@stefan-betz.net>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Aaron Schaefer <aaron@elasticdog.com>
# Contributor: N. I. - izmntuk
pkgname=dar
pkgver=2.6.11
pkgrel=1
pkgdesc='A full featured command-line backup tool, short for Disk ARchive'
arch=('i686' 'x86_64')
url='http://dar.linux.free.fr/'
license=('GPL')
depends=('libgcrypt' 'zlib' 'lzo' 'bzip2' 'xz' 'attr')
optdepends=('perl: for running some samples'
'librsync: for delta binary')
makedepends=('doxygen')
source=("http://downloads.sourceforge.net/project/dar/dar/${pkgver}/dar-${pkgver}.tar.gz")
sha512sums=('fcf6f1a1792a7da52859439fa7d5284905391081a8a0adab3d6fa5d4811b238f75b37003022ed5558661a7545230fad2768517fbfe727a0df415ade4c230e509')
backup=('etc/darrc')
options=('!libtool')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
## --enable-threadar: EXPERIMENTAL multithread support
if [[ "${CARCH}" == x86_64 ]];then
EXTRA_OPTIONS="--enable-mode=64"
elif [[ "${CARCH}" == i686 ]];then
EXTRA_OPTIONS="--enable-mode=32"
fi
./configure --prefix=/usr --sysconfdir=/etc --disable-dar-static --disable-static --disable-upx --disable-build-html ${EXTRA_OPTIONS}
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" pkgdatadir="/usr/share/doc/${pkgname}/html" install
install -d "${pkgdir}/usr/share/doc/${pkgname}"
install -pm644 AUTHORS ChangeLog NEWS README THANKS TODO "${pkgdir}/usr/share/doc/${pkgname}"
rm -rf "${pkgdir}/usr/share/doc/dar/html/man"
}
|