summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 63a8caf197aacd386367d0174f56434da3e45b00 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: James Brink <brink.james@gmail.com>
# Contributor: Chih-Hsuan Yen <yan12125@gmail.com>
# Contributor: James An <james@jamesan.ca>

_pkgname=darling-dmg
pkgname="$_pkgname-git"
pkgver=v1.0.4.r73.g97a92a6
pkgrel=4
pkgdesc="FUSE module for .dmg files (containing an HFS+ filesystem)"
arch=("i686" "x86_64")
url="https://www.darlinghq.org"
license=('GPL3')
depends=("openssl" "bzip2" "libxml2" "fuse2")
makedepends=("git" "cmake" "fuse2" "boost")
provides=("$_pkgname=$pkgver")
source=("git+https://github.com/darlinghq/darling-dmg.git")
md5sums=("SKIP")

pkgver() {
  cd "$_pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$_pkgname"
	mkdir -p build
}

build() {
	cd "$_pkgname/build"
	cmake ../ -DCMAKE_INSTALL_PREFIX=/usr -DWITH_TESTS=1 -DCMAKE_BUILD_TYPE=Release
	make -j$(getconf _NPROCESSORS_ONLN)
}

check() {
	cd "$_pkgname/build"
	make test
}

package() {
	cd "$_pkgname/build"
	make DESTDIR="$pkgdir" install
}