blob: 05d578105eb45bc9bb6dfa3eb6a514bfa294f909 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Frederik Schwan <frederik dot schwan at linux dot com>
pkgbase=datagrip
pkgname=(datagrip datagrip-jre)
pkgver=2019.1.4
pkgrel=1
pkgdesc='Smart SQL Editor and Advanced Database Client Packed Together for Optimum Productivity'
arch=('any')
url='http://www.jetbrains.com/datagrip/'
license=('Commercial')
makedepends=('rsync')
conflicts=('0xdbe' '0xdbe-eap')
options=('!strip')
source=(https://download.jetbrains.com/${pkgbase}/${pkgbase}-${pkgver}.tar.gz
jetbrains-datagrip.desktop)
sha512sums=('c2479c0b26c0e87c151aa9b9b201e2b398aea4b6eb3d774c8c710d3d1d477793d6117c99efb14752caac890543346414cc474a5bafc31122056de4228ec75c6a'
'6fa0fb2eba7017f2818a5e9d8e44d43a050fdb5b13c7dd1650fae472191f892424f904009e2ba675d5f75200e7e2f42dad95741e94b16355a8ce9eb07bd8660b')
package_datagrip() {
optdepends=('datagrip-jre: JetBrains custom Java Runtime (Recommended)'
'java-runtime: JRE - Required if datagrip-jre is not installed')
install -d -m 755 "${pkgdir}/opt/"
install -d -m 755 "${pkgdir}/usr/bin/"
install -d -m 755 "${pkgdir}/usr/share/applications/"
install -d -m 755 "${pkgdir}/usr/share/pixmaps/"
rsync -rtl "${srcdir}/DataGrip-${pkgver}/" "${pkgdir}/opt/${pkgbase}" --exclude=/jre64
ln -s "/opt/${pkgbase}/bin/${pkgbase}.sh" "${pkgdir}/usr/bin/${pkgbase}"
install -D -m 644 "${srcdir}/jetbrains-${pkgbase}.desktop" "${pkgdir}/usr/share/applications/"
install -D -m 644 "${pkgdir}/opt/${pkgbase}/bin/${pkgbase}.png" "${pkgdir}/usr/share/pixmaps/${pkgbase}.png"
}
package_datagrip-jre() {
install -d -m 755 "${pkgdir}/opt/${pkgbase}"
rsync -rtl "${srcdir}/DataGrip-${pkgver}/jre64" "${pkgdir}/opt/${pkgbase}"
}
|