blob: c2bdf97e94571c6a2e647185a105ef61111214e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Dmitry Chusovitin <dchusovitin@gmail.com>
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
pkgbase=datagrip-eap
_pkgbase=${pkgbase/-eap/}
pkgname=(datagrip-eap datagrip-eap-jre)
pkgver=232.7295.8
_pkgver=${pkgver}
#_pkgver=2022.2
pkgrel=1
pkgdesc='Smart SQL Editor and Advanced Database Client Packed Together for Optimum Productivity (EAP)'
arch=('any')
url='https://www.jetbrains.com/datagrip/'
license=('custom:jetbrains')
depends=('glib2')
conflicts=('0xdbe' '0xdbe-eap')
options=('!strip')
source=("https://download.jetbrains.com/${_pkgbase}/${_pkgbase}-${pkgver}.tar.gz"
jetbrains-datagrip-eap.desktop
LICENSE)
b2sums=('a8d2d650c0dd6b42ffc56e74cb6cbdc84f8d4883ff0dd83736778ed43092aaac0bebcbbb18e06d6a34675c52a4a46066fea8f0ce2a4a91bb138693dc9eb670fb'
'780569cb12b9f5d2475363c7b9c28d903f5a79806aaeea634973664b7cdac0ef281519024fa784b20d7e0062bf9b69e2bca3036bca58e6ee43a475609ea42a1c'
'dadaf0e67b598aa7a7a4bf8644943a7ee8ebf4412abb17cd307f5989e36caf9d0db529a0e717a9df5d9537b10c4b13e814b955ada6f0d445913c812b63804e77')
package_datagrip-eap() {
optdepends=('datagrip-eap-jre: JetBrains custom Java Runtime (Recommended)'
'java-runtime: JRE - Required if datagrip-jre is not installed')
install -dm755 "${pkgdir}"/opt/
install -dm755 "${pkgdir}"/usr/bin/
install -dm755 "${pkgdir}"/usr/share/applications/
install -dm755 "${pkgdir}"/usr/share/pixmaps/
cp -a "${srcdir}"/DataGrip-${_pkgver}/ "${pkgdir}"/opt/${pkgbase}
rm -rf "${pkgdir}"/opt/${pkgbase}/jbr
ln -s /opt/${pkgbase}/bin/${_pkgbase}.sh "${pkgdir}"/usr/bin/${pkgbase}
install -m644 "${srcdir}"/jetbrains-${pkgbase}.desktop "${pkgdir}"/usr/share/applications/
install -m644 "${pkgdir}"/opt/${pkgbase}/bin/${_pkgbase}.svg "${pkgdir}"/usr/share/pixmaps/${pkgbase}.svg
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
}
package_datagrip-eap-jre() {
pkgdesc='JBR (JetBrains Runtime) for DataGrip - a patched JRE'
url='https://confluence.jetbrains.com/display/JBR/JetBrains+Runtime'
install -dm755 "${pkgdir}"/opt/${pkgbase}
cp -a "${srcdir}"/DataGrip-${_pkgver}/jbr "${pkgdir}"/opt/${pkgbase}
}
|