blob: 75e550da52cd7d648a8e8c6193db2efd08426de5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# $Id$
# Maintainer: Tom Gundersen <teg@jklm.no>
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Link Dupont <link@subpop.net>
# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
pkgbase=dbus-selinux
pkgname=('dbus-selinux' 'libdbus-selinux')
pkgver=1.8.16
pkgrel=2
pkgdesc="Freedesktop.org message bus system with SELinux support"
url="http://www.freedesktop.org/Software/dbus"
arch=(i686 x86_64)
license=('GPL' 'custom')
groups=('selinux')
makedepends=('libx11' 'systemd-selinux' 'xmlto' 'docbook-xsl' 'audit' 'libselinux')
source=(http://dbus.freedesktop.org/releases/dbus/dbus-$pkgver.tar.gz{,.asc}
30-dbus)
md5sums=('020824a38850501e7d6ba8307a7c5ac3'
'SKIP'
'6683a05bd749929ef9442816c22c3268')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90') # Simon McVittie <simon.mcvittie@collabora.co.uk>
build() {
cd dbus-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=dbus \
--with-system-pid-file=/run/dbus/pid \
--with-system-socket=/run/dbus/system_bus_socket \
--with-console-auth-dir=/run/console/ \
--enable-inotify --disable-dnotify \
--disable-verbose-mode --disable-static \
--disable-tests --disable-asserts \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--enable-systemd \
--enable-selinux --enable-libaudit
make
}
package_dbus-selinux(){
depends=('libdbus-selinux' 'expat' 'audit' 'libselinux' 'libsystemd-selinux')
optdepends=('libx11: dbus-launch support')
provides=('dbus-core' "${pkgname/-selinux}=${pkgver}-${pkgrel}" "selinux-${pkgname/-selinux}=${pkgver}-${pkgrel}")
conflicts=('dbus-core' "${pkgname/-selinux}" "selinux-${pkgname/-selinux}")
replaces=('dbus-core' "${pkgname/-selinux}")
cd dbus-$pkgver
# Disable installation of libdbus
sed -i -e 's/^SUBDIRS = dbus/SUBDIRS =/' Makefile
make DESTDIR="$pkgdir" install
rm -rf "${pkgdir}/var/run"
rm -rf "${pkgdir}/usr/lib/pkgconfig"
install -Dm755 ../30-dbus "$pkgdir/etc/X11/xinit/xinitrc.d/30-dbus.sh"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/dbus-selinux/COPYING"
}
package_libdbus-selinux(){
pkgdesc="DBus library"
depends=('glibc')
provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}")
conflicts=("${pkgname/-selinux}")
replaces=("${pkgname/-selinux}")
cd dbus-$pkgver
make DESTDIR="$pkgdir" -C dbus install
make DESTDIR="$pkgdir" install-data-am
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/libdbus-selinux/COPYING"
}
|